Pulling out common terms when simplifying complicated equations

Question

I have a complicated expression where common terms are apparent but Simplify[] and FullSimplify[] don't appear able, even with plenty of assumptions added, to reduce down to a simpler form with common terms recognised so that I can give them a symbol and simplify the expressions acordingly. A simpler example which demonstrates is

h (140 + Current - 
   lastU1 + (lastV1 + 
      1/2 h (140 + Current - lastU1 + (5 + 0.04 lastV1) lastV1)) (5 + 
      0.04 (lastV1 + 
         1/2 h (140 + Current - lastU1 + (5 + 0.04 lastV1) lastV1))))

with obvious common terms being

140 + Current - lastU1   -> Alpha
(5 + 0.04 lastV1) lastV1 -> Beta

With these and one further common term which contains them both recognised

(lastV1 + 1/2 h (Alpha + Beta)) -> Gamma

this expression can be reduced to

h (Alpha + Gamma (5 + 0.04` Gamma))

I have played with Factor[], Collect[] and many others but nothing seems to do what I need. I am sure that Mathematica is capable of doing what I am looking for, so I am asking the experts here for tips for how best to go about it.

As a matter of interest, these expressions are going to be compiled into C eventually and I have found this to produce output of interest in terms of structuring the algebraic reduction

Experimental`OptimizeExpression[ expression , OptimizationLevel -> 2]

but I would still like more control over the manipulation before I get to this stage.

Many thanks in advance

Michael

Answer 1

While this won't work in general with very complicated expressions (see the other post for more general approaches), you could try simple replacement rules to get a reasonable degree of simplification. If you had only linear relations, that would work for sure. In the case of your 'toy' example

expr = h (140 + Current - lastU1 + (lastV1 + 1/2 h (140 + Current - 
        lastU1 + (5 + 0.04 
              lastV1) lastV1)) (5 + 0.04 (lastV1 + 1/2 h (140 +
                     Current - lastU1 + (5 + 0.04 lastV1) lastV1))))

the second rule below works only because it had the terms to be replaced in the very same form throughout the whole expression.

expr /. {lastU1 -> 140 + Current - Alpha, (5 + 0.04 lastV1) -> Beta/lastV1}

then you can apply the last rule

% /. lastV1 -> Gamma - 1/2 h (Alpha + Beta)

(Alpha + (0.04 Gamma + 5) Gamma) h

Often, after applying the rules, it is a good idea to feed the resulting expression to Simplify.

Answer 2

I am avoiding Beta and Gamma but using symbols as the former are special symbols in Mathematica.

The rules can be applied for simplification:

exp = h (140 + Current - 
    lastU1 + (lastV1 + 
       1/2 h (140 + Current - 
          lastU1 + (5 + 0.04 lastV1) lastV1)) (5 + 
       0.04 (lastV1 + 
          1/2 h (140 + Current - lastU1 + (5 + 0.04 lastV1) lastV1))))

Then replacing all:

(exp //. {140 + Current - lastU1 -> \[Alpha],
    (5 + 0.04 lastV1) lastV1 -> \[Beta]}) //. (lastV1 + 
    1/2 h (\[Alpha] + \[Beta])) -> \[Gamma]

yields:

h (\[Alpha] + (5 + 0.04 \[Gamma]) \[Gamma])