I would like to check the following integration:

Integrate[y Integrate[1/x BesselJ[1, x Exp[I π/4]] BesselJ[1, x Exp[-I π/4]],
          {x, 0, y}], {y, 0, r}]

Mathematica 9.0 is not able to evaluate the integral. However, Maple 16 gives the following result:

r^4/32 * hypergeometric([1/2],[3/2,3/2,2,2],r^4/64) 

Is this result correct?


Mathematica can do it, but need to use the HypergeometricPFQ form, as follows. For some reason, Mathematica can't do it in BesselJ. May be a report should be send to support@wolfram.com

First to show that the HypergeometricPFQ form is equivalent to the BesselJ form:

 bad = BesselJ[1, x*Exp[I*Pi/4]]*BesselJ[1, x*Exp[-I*Pi/4]];
 good = 1/4 x^2 HypergeometricPFQ[{},{2},-1/4 I x^2] HypergeometricPFQ[{},{2},1/4 I x^2]
 FullSimplify[bad - good]
 (* 0 *)

Now the integral works, and gives the result shown by Maple. So Maple is correct :)

 WL = Integrate[y*Integrate[1/x*good, {x, 0, y}], {y, 0, r}]
 (* -(1/32) I r^2 Sqrt[-r^4]  HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64] *)

To verify the above is the same as Maple's:

maple = 1/32*r^4*HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, 1/64 r^4];
Grid[Join[{{"r", "WL", "Maple"}}, 
  N@Table[{i, WL /. r -> i, maple /. r -> i}, {i, 0, 10, 1}]]]

check Maple's result

  • $\begingroup$ Hi Naseer, Thanks alot for spending your time. $\endgroup$
    – learner123
    Nov 28 '13 at 9:21
  • $\begingroup$ @Nasser, I am strongly impressed by your answer. $\endgroup$ Nov 28 '13 at 9:24
  • $\begingroup$ Hi Naseer, Thanks alot for spending your time and clarifying my doubt. I would be greatful if you could tell me know how you come up with the equation "good", i.e representing BesselJ in terms of Hypergeometric function. I do agree that we can convert the BesselJ interms of Hypergeometric functions. Have you done it manually or Mathematica can do it. I was searching for the command on representing the BesselJ in terms of Hypergeometric series. $\endgroup$
    – learner123
    Nov 28 '13 at 9:33
  • $\begingroup$ @AlexeiBoulbitch thanks :) @ learner123, actually I was just lucky I found it. I was hoping if I can find different form, that will send Integrate into different code path to allow it to do it. So I looked at all the different possible transformations to other special functions from BesselJ, tried few and none worked, and just before I gave up, HypergeometricPFQ worked. I used Maple's nice convert commands to try different forms, then copied each form to Mathematica and tried them to see if it will work or not. That is how I found it. $\endgroup$
    – Nasser
    Nov 28 '13 at 9:38
  • $\begingroup$ Naseer, Thanks alot. $\endgroup$
    – learner123
    Nov 29 '13 at 3:48

It looks like the trick making the integration possible is just a change of variable Exp[-I Pi/4] x -> z. Defining :

g[z_, y_] = Exp[-I Pi/4] y/z BesselJ[1, z] BesselJ[1, I z]


Integrate[Integrate[ Exp[I Pi/4] g[z, y], {z, 0, Exp[-I Pi/4] y}], {y, 0, r}]
(* 1/32 r^4 HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64] *)

As it turns out, although Mathematica is unable to deal with the integral as it stands, using the Kelvin functions yields an answer equivalent to the one returned by Maple.

In particular,

Integrate[(y/x) (KelvinBer[1, x]^2 + KelvinBei[1, x]^2), {y, 0, r}, {x, 0, y}]
   1/32 r^4 HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64]

where I used one of the defining relations between Kelvin and Bessel functions given in the DLMF.


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.