2
$\begingroup$

I need to make semitransparent coordinate plane(s) at ParametricPlot3D with one parameter. If I add the second parameter the curves becomes ugly.

 GraphicsRow[{
   ParametricPlot3D[{
     {Sin[u], Tan[u], u/10}, 
     0.5 {Cos[u], Sin[u], u/10}}, 
   {u, -20, 20},  BoxRatios -> {1, 1, 1}], 
   ParametricPlot3D[{
     {Sin[u], Tan[u], u/10}, 
     0.5 {Cos[u], Sin[u], u/10}, 
     {u/10, v/10, 0}}, 
  {u, -20, 20}, {v, -20, 20}, BoxRatios -> {1, 1, 1}]}]

enter image description here

enter image description here

How I can fix it?

$\endgroup$

2 Answers 2

3
$\begingroup$

Just make two separate graphics and combine them using Show

Show[{ParametricPlot3D[{{Sin[u], Tan[u], u/10}, 
    0.5 {Cos[u], Sin[u], u/10}}, {u, -20, 20}], 
  ParametricPlot3D[{u/10, v/10, 0}, {u, -20, 20}, {v, -20, 20}, 
   PlotStyle -> {Opacity[0.3, Magenta]}]}, BoxRatios -> {1, 1, 1}]

Mathematica graphics

$\endgroup$
1
$\begingroup$

In versions 10+, you can use InfinitePlane:

Show[ParametricPlot3D[{{Sin[u], Tan[u], u/10}, 0.5 {Cos[u], Sin[u], u/10}}, {u, -20, 20}, 
  BoxRatios -> {1, 1, 1}], 
 Graphics3D@{Opacity[.3, Blue], InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}}]}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.