Printing intermediate calculations in an external file, while suppressing the output in the notebook

Question

I'm trying to construct a text-file that contains all the operations that Mathematica performs when evaluating an expression. However, i'd like to suppress all output in the notebook in which I'm doing the calculations.

For instance printing the operations for calculating the root of x^2 = 1 in Mathematica.txt is done as follows:

stream = OpenWrite["c:/Data/Mathematica.txt"];
AppendTo[$Output, stream];
Print[TracePrint[Solve[x^2 == 1, x]]];
Close[stream];
$Output = Most[$Output];

which gives the following output in my Notebook:

Solve[x^2==1,x]    
Solve  
x^2==1    
Equal    
(x^2)     
Power 
x
2
1 
x 
x^2==1
x^2==1
{{x->-1},{x->1}}
{{x->-1},{x->1}}

and the following output in Mathematica.txt

 HoldForm[Solve[x^2 == 1, x]]
  HoldForm[Solve]
  HoldForm[x^2 == 1]
   HoldForm[Equal]
   HoldForm[x^2]
    HoldForm[Power]
    HoldForm[x]
    HoldForm[2]
   HoldForm[1]
  HoldForm[x]
  HoldForm[x^2 == 1]
  HoldForm[x^2 == 1]   
 HoldForm[{{x -> -1}, {x -> 1}}]
{{x -> -1}, {x -> 1}}

Is there a way to not get the first block of 'output'?

Thanks a lot!

Answer 1

This might work:

oldout = $Output; stream = OpenWrite["c:/Data/Mathematica.txt"]; $Output = stream;
Write[stream, TracePrint[Solve[x^4 == 1, x]]];
Close[stream]; $Output = oldout;

The concept is to redirect the output to your file and than recover the original output stream.

EDIT:

Along the lines suggested by Chris Chiasson, a more "structured" solution may be:

ClearAll[redirectOutput];

Attributes[redirectOutput] = {HoldRest};

redirectOutput[file_String, expr_] := 
Block[{$Output = OpenWrite[file, PageWidth -> Infinity], result},
        result = expr;
        Close@ $Output;
    result
];

As an example:

redirectOutput["C:\\debug.txt",
  TracePrint[Solve[x^4 == 1, x]]
]

sends all the printed output to the file and returns only the last value:

{{x->-1},{x->-I},{x->I},{x->1}}