Control multiple locators along a plot

Question

Update 1

@ Michael E2, my effort - for what it is worth!:

f[x_] := Im[(-1)^(-1 - x/2) 2^(1 - x) \[Pi]^-x x! Zeta[x]];
f[a_] := -a Zeta[1 - a];
Manipulate[With[{{x0 = Clip[p[[1]], {3, 10}]}, {a0 = Clip[p[[1]], {3, 10}]}},
Plot[{f[x], f[a]}, {x, 3, 10}, ImagePadding -> 20, LabelStyle -> (FontFamily -> 
"Ariel"), Epilog -> {PointSize[Large], Red, Tooltip[Point[#], #] &@{x0, f[x0], a0, 
f[a0]}}]], {{p, {3, 0}}, Locator, Appearance -> None}, AppearanceElements -> None]

Original question

I would like to control two locators at once (both moving with same x value), outputting 2 sets of coordinates simultaneously. The plot I am working looks like this:

generated by the following code:

Plot[{Im[(
N[Zeta[x]] x!)/(\[Pi]^x (2^(x - 1) (-1)^(x/2 + 1)))], 
-x Zeta[1 - x]}, {x, 3, 10}, Epilog -> {PointSize[Medium], Red, 
Point[{{5, -5 Zeta[1 - 5]}, 
{5, Im[(N[Zeta[5]] 5!)/(\[Pi]^5 (2^(5 - 1) (-1)^(5/2 + 1)))]}}]}]

Michael E2 and Timothy Wofford provided a code that controls one locator in this post. I would like to achieve the same thing with multiple locators (ideally by moving one locator with cursor & both locators moving with equal x values at the same time - both generating their separate coordinates).

If possible also, I would like the manipulate cell to output the value of a function of each point as it moves, along with the sum of both functions. I hope I am making sense here!

Answer 1

Please compare this to your attempt and try to understand the slight changes I made.

f[x_] := Im[(-1)^(-1 - x/2) 2^(1 - x) \[Pi]^-x x! Zeta[x]];
g[a_] := -a Zeta[1 - a];
Manipulate[
 With[{x0 = Clip[p[[1]], {1., 10. (*or Infinity*)}]}, 
  Plot[{f[x], g[x]}, {x, 0, 10}, 
   Epilog -> {PointSize[Large], 
     Blue,Tooltip[Point[#], #] &@{x0, f[x0]},
     Red, Tooltip[Point[#], #] &@{x0, g[x0]}
 }, PlotLabel -> {x0, f[x0]}]], {{p, {4, 0}}, Locator, 
Appearance -> None}, AppearanceElements -> None]