4
$\begingroup$

I wrote the following to generate a multiset with the same number of items over a fixed range:

ConstantArray[#, 3]& /@ Range[9] // Flatten

{1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9}

This approach uses four named functions (Range, Flatten, ConstantArray and Map (/@)) and one pure function (ending with &).
Is there a way to do the same thing with fewer functions?

Also, if I wanted to have variable numbers of items in my multiset how would I do that?
For example, let's say I wanted a multiset like { 1, 1, 1, 1, 2, 2, 3, 4, 4, 4, 6, 6, 7, 8, 8, 8 }.

By a "variable number of items" I do not mean random, I mean a specified variable number.

|improve this question
$\endgroup$
6
$\begingroup$ 
   f[n_, k_] := Table[ConstantArray[i, n], {i, k}]

Now you can vary the number of items of each:

f[3, 9] // Flatten

{1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9}

f[4, 10] // Flatten

{1, 1, 1, 1, 2, 2, 2, 2, 3, 3, 3, 3, 4, 4, 4, 4, 5, 5, 5, 5, 6, 6, 6, 6, 7, 7, 7, 7, 8, 8, 8, 8, 9, 9, 9, 9, 10, 10, 10, 10}

for random Situation:

fRandom[n_, k_] := Table[ConstantArray[i, RandomInteger[{1, n}]], {i, k}]

For your second situation try this;

Inner[ConstantArray, Range[8], {4, 2, 1, 3, 0, 2, 1, 3}, List] // Flatten

{1, 1, 1, 1, 2, 2, 3, 4, 4, 4, 6, 6, 7, 8, 8, 8}

|improve this answer
$\endgroup$
  • $\begingroup$ for constant k, one could also do: Flatten[Table[i, {i, 10}, {j, 3}]] $\endgroup$ – Pinguin Dirk Oct 17 '13 at 17:05
  • $\begingroup$ @PinguinDirk. Fo shizzle :) $\endgroup$ – RunnyKine Oct 17 '13 at 17:09
  • $\begingroup$ I do not want random numbers of items. I want specific numbers of each item in the multiset. $\endgroup$ – Tyler Durden Oct 17 '13 at 18:11
  • $\begingroup$ @TylerDurden, Well, initially you did not specify this. How exactly do you want to specify those numbers, you need to be more specific so we know what you want. $\endgroup$ – RunnyKine Oct 17 '13 at 18:33
  • $\begingroup$ @TylerDurden. See my update. $\endgroup$ – RunnyKine Oct 17 '13 at 19:32
11
$\begingroup$

Ad. I

These should be the most efficient and tersest

Ceiling[ Range @ 27 / 3 ]

or

Array[ Ceiling[#/3] &, 27]

yield

{1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9}

they both can be tersely written in the Front End (see details of Ceiling) as:

enter image description here

or

enter image description here

Ad.II

For the second problem there are many approaches, here is a solution with a determined number of items ( Count[{1, 1, 1, 1, 2, 2, 3, 4, 4, 4, 6, 6, 7, 8, 8, 8}, #] & /@ Range[8]) as in your example:

Inner[ ConstantArray, Range @ 8, {4, 2, 1, 3, 0, 2, 1, 3}, Join]

{1, 1, 1, 1, 2, 2, 3, 4, 4, 4, 6, 6, 7, 8, 8, 8}

or 

Flatten @ MapThread[ ConstantArray, {Range @ 8, {4, 2, 1, 3, 0, 2, 1, 3}}]
|improve this answer
$\endgroup$
  • $\begingroup$ I do not want random numbers of items. I want specific numbers of each item in the multiset. $\endgroup$ – Tyler Durden Oct 17 '13 at 18:12
  • $\begingroup$ @TylerDurden So you've got it. $\endgroup$ – Artes Oct 17 '13 at 18:24
6
$\begingroup$

To me, the most straightforward way seems to be:

Flatten[ConstantArray[Range[9], 3], {2, 1}]
(* {1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9} *)

i.e., instead of repeating each element in the list 3 times, you repeat the entire list 3 times and flatten it using the appropriate second argument.

|improve this answer
$\endgroup$
  • $\begingroup$ +1 -- this is the same method I use, though usually with infix: Range@9 ~ConstantArray~ 3 ~Flatten~ {2, 1} :-) $\endgroup$ – Mr.Wizard♦ Dec 29 '13 at 20:08
  • $\begingroup$ @Mr.Wizard Pfft lame... 1 ~Range~ 9 ~ConstantArray~ 3 ~Flatten~ (2 ~List~ 1) :P $\endgroup$ – rm -rf♦ Dec 29 '13 at 20:59
  • $\begingroup$ reductio ad absurdum $\endgroup$ – Mr.Wizard♦ Dec 29 '13 at 22:33
4
$\begingroup$

No Rules?, so this is one from Szabolc's site:

 Range[9] /. n_Integer :> Sequence[n, n, n]

{1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9}

Since you haven't described how those numbers should vary for second part, maybe something like:

Sort@RandomInteger[{1, 10}, 27]

{1, 2, 3, 3, 3, 3, 4, 4, 4, 4, 5, 5, 5, 6, 6, 7, 7, 7, 7, 7, 8, 8, 8, 8, 9, 9, 10}

Ok, let's say you have list of numbers which are referring to consecutive integers repetition:

Flatten@MapIndexed[ConstantArray[#2, #] &, {4, 3, 5, 1, 2, 3}]

{1, 1, 1, 1, 2, 2, 2, 3, 3, 3, 3, 3, 4, 5, 5, 6, 6, 6}

Or similar:

i = 0; 
Flatten[ConstantArray[++i, #] & /@ {4, 3, 5, 1, 2, 3}]

{1, 1, 1, 1, 2, 2, 2, 3, 3, 3, 3, 3, 4, 5, 5, 6, 6, 6}
|improve this answer
$\endgroup$
  • $\begingroup$ I do not want random numbers of items. I want specific numbers of each item in the multiset. For example, in the case shown I want four 1's, two 2's, one 3, three 4's, no fives, two 6's, one 7, and three 8's. $\endgroup$ – Tyler Durden Oct 17 '13 at 18:14
  • $\begingroup$ @TylerDurden ok :) see my edit $\endgroup$ – Kuba♦ Oct 17 '13 at 19:35
3
$\begingroup$ 
Flatten[ Range[ 1, 9, {1, 1, 1}], {2, 1}] 
Join @@ Table[ i, {i, 9}, {3}]
Join @@ Array[ # &, {9, 3}]
Table[ 1/9 (3 n - 2 Sqrt[3] Cos[(2 π n)/3 + π/6] + 3), {n, 27}]

{1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4, 5, 5, 5, 6, 6, 6, 7, 7, 7, 8, 8, 8, 9, 9, 9}

|improve this answer
$\endgroup$
  • $\begingroup$ This answer gets the booby prize, or the tongue-in-cheek prize, as the case may be. $\endgroup$ – Tyler Durden Oct 29 '13 at 16:45
  • $\begingroup$ +1 for the first one; a nice way to use only two functions! $\endgroup$ – Mr.Wizard♦ Dec 29 '13 at 20:11
2
$\begingroup$

For your second question:

MapThread[ConstantArray, {Range[9], RandomInteger[{1, 3}, 9]}] // Flatten
(* {1, 1, 1, 2, 2, 3, 4, 4, 4, 5, 5, 5, 6, 6, 7, 7, 7, 8, 9} *)
|improve this answer
$\endgroup$
1
$\begingroup$

Yet another way, for the first part:

With[{n = 3, k = 10}, Quotient[Range[k n], n, -n+1]] (* incorporating Artes' suggestion *)

Updated:

For the second part, an approach not already covered in the other answers:

Module[{i = 1, reps = {4, 5, 1, 3}}, 
   Fold[#1~Join~ConstantArray[ i++, #2] &, {}, reps]] (* reps are variable repetition factors *)

{1, 1, 1, 1, 2, 2, 2, 2, 2, 3, 4, 4, 4}

|improve this answer
$\endgroup$
  • 1
    $\begingroup$ Very nice (+1) however I'd rather do this Quotient[ Range[3 9], 3, -2] to get exaclty what has been expected. Consider to answer another question in the OP. $\endgroup$ – Artes Dec 29 '13 at 22:33
  • $\begingroup$ Oh sorry - for some reason I imagined the sequence began with zeros. I'll modify my answer. $\endgroup$ – Aky Dec 29 '13 at 22:42
  • $\begingroup$ Why do you need With? There is no need for Range[1, k n] since it's equal to Range[k n]. And what about variable number of items? $\endgroup$ – Artes Dec 29 '13 at 22:50
  • $\begingroup$ Oops, that was a mistake - I was really sleepy when I wrote that. Fixed now. The With is just for convenience and generalization, if someone wants to use the same method with a different range or repetition value. (I could've written it as a function.) $\endgroup$ – Aky Dec 30 '13 at 5:59

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.