How can I get the exact solution of this equation (inequality equation)?

Question

I want to solve the equation and inequality equation $$\sqrt{8\cdot 16^x - \dfrac{1}{2}\cdot 9^x }= 3\cdot 4^x - 3^x$$ and $$\sqrt{8\cdot 16^x - \dfrac{1}{2}\cdot 9^x } \leqslant 3\cdot 4^x - 3^x.$$ The correct of the given equation is $$-\log_{\dfrac{3}{4}}\left (3+\dfrac{\sqrt{30}}{2}\right ).$$ I tried

Reduce[Sqrt[8 16^x - 1/2 9^x] == 3 4^x - 3^x, x, Reals]

x == Root[{2 + Sqrt[2] 3^-#1 Sqrt[2^(4 (1 + #1)) - 3^(2 #1)] - 
 6 E^(2 Log[2] #1 - Log[3] #1) &, 6.0734320063313606675}]

With inequality, I tried

Reduce[Sqrt[8 16^x - 1/2 9^x] <= 3*4^x - 3^x, x, Reals]

x >= Root[{2 + Sqrt[2] 3^-#1 Sqrt[2^(4 (1 + #1)) - 3^(2 #1)] - 
 6 E^(2 Log[2] #1 - Log[3] #1) &, 6.0734320063313606675}]

How can I get the correct solution?

Answer 1

This is based on @Nasser solution but improved to make it more general.

If it helps when there are no roots then let's power both sides to 2. But we have to remeber that this will probably lead to double solution. There is a way to get rid of it too:

Equality

expr = Sqrt[8 16^x - 1/2 9^x] == 3 4^x - 3^x;

Solve[ Thread[Power[expr, 2], Equal] && expr, x, Reals]

$\left\{\left\{x\to \frac{\log \left(6+\sqrt{30}\right)-\log (2)}{2 \log (2)-\log (3)}\right\}\right\}$

Inequality

expr = Sqrt[8 16^x - 1/2 9^x] <= 3 4^x - 3^x;

Reduce[Thread[Power[expr, 2], LessEqual] && expr, x, Reals] // Quiet

$x\geq \frac{\log \left(6+\sqrt{30}\right)-\log (2)}{2 \log (2)-\log (3)}$

Answer 2

If you first remove the sqrt it seems to help Reduce

\begin{align*} \sqrt{8\left( 16^{x}\right) -\frac{1}{2}9^{x}} & =3\left( 4^{x}\right) -3^{x}\\ \frac{1}{2}\ln\left( 8\left( 16^{x}\right) -\frac{1}{2}9^{x}\right) & =\ln\left( 3\left( 4^{x}\right) -3^{x}\right) \\ \ln\left( 8\left( 16^{x}\right) -\frac{1}{2}9^{x}\right) & =\ln\left( \left[ 3\left( 4^{x}\right) -3^{x}\right] ^{2}\right) \\ 8\left( 16^{x}\right) -\frac{1}{2}9^{x} & =3^{2x}+9\left( 4^{2x}\right) -6\left( 3^{x}4^{x}\right) \end{align*}

ps. To remove the sqrt, much easier to use suggestion by Kuba. No need for taking logs.

Thread[Power[Sqrt[8 16^x - 1/2 9^x] == 3 4^x - 3^x, 2], Equal];
Reduce[%, x, Reals]

Now:

The second solution is what you had

 Simplify[-Log[3/4, (3 + Sqrt[30]/2)] == %[[2, 2]]]
 (* True *)

Answer 3

Since Reduce[Sqrt[8 16^x - 1/2 9^x] == 3 4^x - 3^x, x] gives Reduce::nsmet: This system cannot be solved with the methods available to Reduce you can only resort to some kind of manipulation. You would need to make it more generic and robust, but the closest to what you'do with paper and pencil is :

eq = Sqrt[8 16^x - 1/2 9^x] - (3 4^x - 3^x) ;
eq2 = (eq /. {3^x -> 4^x y, 9^x -> 4^(2 x) y^2}) (* divide by 4^x *)
eq3 = eq2 /. {x -> 0} (* factor out common  terms assuming they are non-zero *)

aux = Reduce[eq3 == 0, y][[2]]
(* 1/3 (6 - Sqrt[30]) *)

Log[3/4, aux] // N (* recall your change of variable *)