4
$\begingroup$

Let $(E_l) : x^4-4x^3+x^2(5-l^2)+4 x l^2-4l^2 = 0$ be an equation with $l$ as a parameter and $x$ as an unknown and $S_l$ the set containing all the real solutions of $(E_l)$.

Then there is a unique value of $l$ verifying $card(S_l) = 1$.

Is there a way in Mathematica to find an approximate value for this $l$ ?

$\endgroup$
7
$\begingroup$

Complex roots come in pairs therefore the equation will have a single real solution only if it has a real double root and two complex root or if it has a quadruple root.

So we require

poly = -4 l^2 + 4 l^2 x + (5 - l^2) x^2 - 4 x^3 + x^4

Solve[{poly == 0, D[poly, x] == 0}, {x, l}, Reals]

This gives us three solutions for l:

{0, -((2 + 2^(1/3))^(3/2)/Sqrt[2]), (2 + 2^(1/3))^(3/2)/Sqrt[2]}

Substituting them back into poly and finding all roots shows that only l == 0 will give double real root and two complex roots.

$\endgroup$
  • $\begingroup$ I'm quite disappointed I didn't think of using the derivative. Very clever solution, thanks ! $\endgroup$ – Cydonia7 Oct 4 '13 at 14:49
5
$\begingroup$
With[{poly = x^4 - 4 x^3 + (5 - l^2) x^2 + 4 l^2 x - 4 l^2},
 With[{sols = 
    DeleteDuplicates@Solve[Discriminant[poly, x] == 0, l, Reals]},
  Select[
   sols,
   Length[DeleteDuplicates@Solve[(poly /. First@#) == 0, x, Reals]] ==
      1 &
   ]
  ]]

(* {{l -> 0}} *)
$\endgroup$
  • $\begingroup$ @Michel E2 If I want to the equation $x^4+2(m+1)x^2 - m - 4 =0$ has three reals solutions. How can I get it? $\endgroup$ – minthao_2011 Oct 5 '13 at 3:52
  • $\begingroup$ @minthao_2011 Should this be a separate question, not a comment? In any case, three (distinct) real solutions implies two simple and one double root. From Discriminant[x^4 + 2 (m + 1) x^2 - 4, x], one sees that only m -> -4 will yield a double root; luckily it also yields two other simple real roots. $\endgroup$ – Michael E2 Oct 5 '13 at 12:24

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.