7
$\begingroup$

I want to fill in the region between the curves.

So far I have this:

Plot[{x + 7, 9 - x^2}, {x, 0, 1.5}, Filling -> {1 -> {2}}]

enter image description here

But I want something like this:

enter image description here

|improve this question
$\endgroup$
  • 3
    $\begingroup$ So what's the logic here? 1) Fill to the left of the point of intersection? 2) Fill when curve 2 is above curve 1? 3) Fill the first enclosure between the two curves? $\endgroup$ – rm -rf♦ Sep 27 '13 at 19:26
  • $\begingroup$ @rm-rf I closed this question because as it has been interpreted it is a duplicate, and I wish to respect the older, original question from a contributing member. However, that makes the answers here somewhat harder to find. Do you think this might be a case where a merge is appropriate? I believe the original can be modified so that all the answers make sense. $\endgroup$ – Mr.Wizard♦ Jan 10 '14 at 10:28
  • $\begingroup$ @Mr.Wizard Why does it make this harder to find? Duplicates show up exactly as any other post and are just as searchable/rep-earnable. It's only the "answerless duplicates" that are automatically redirected. But I agree that a merge might not be all that bad (esp. since only belisarius has an answer there), and Anon has an apparently general version of a shading function... $\endgroup$ – rm -rf♦ Jan 10 '14 at 16:10
  • $\begingroup$ @rm-rf I meant somewhat harder to find than if the close went the other way. Since you agree this is a good candidate for a merge, e.g. there is no Accepted answer here, I shall do that tomorrow unless you do it first. $\endgroup$ – Mr.Wizard♦ Jan 10 '14 at 16:50
13
$\begingroup$

Alternatively, you can use the +/- option of Filling

Plot[{x + 7, 9 - x^2}, {x, 0, 1.5}, Filling -> {1 -> {{2}, {LightBlue, White}}}]

Mathematica graphics

|improve this answer
$\endgroup$
  • $\begingroup$ I would use None not White. $\endgroup$ – rcollyer Sep 27 '13 at 19:34
  • $\begingroup$ @rcollyer While I'm changing the colors, do you know off hand what the default blue is? $\endgroup$ – bobthechemist Sep 27 '13 at 19:37
  • 1
    $\begingroup$ The simplest way to get that color is to run, ColorData[1][1]. Then fiddle with the Opacity until you're content. $\endgroup$ – rcollyer Sep 27 '13 at 19:38
  • 1
    $\begingroup$ @bobthechemist Your answer was a few seconds before. I was late while extracting the default color from Plot[...]//InputForm :) $\endgroup$ – ybeltukov Sep 27 '13 at 19:47
  • 6
    $\begingroup$ No need to extract any color... just use Automatic :) $\endgroup$ – rm -rf♦ Sep 27 '13 at 19:50
4
$\begingroup$

It's like rm-rf says in his comments, it's not really clear what the logic is. There are already plenty of ways to use Filling to produce the requested plot but here's a more general function to facilitate arbitrary logic:

shadeBoundedArea[plot_, region_] := Module[{rangex, rangey},
  {rangex, rangey} = PlotRange /. AbsoluteOptions[plot];
  Show[
   plot,
   RegionPlot[region, Evaluate@{x, Sequence @@ rangex}, 
    Evaluate@{y, Sequence @@ rangey}]
   ]
  ]

Clear[x, y];

p = Plot[{f1[x], f2[x]}, {x, 0, 1.5}]

shadeBoundedArea[p, f1[x] < y < f2[x]]

enter image description here

|improve this answer
$\endgroup$
3
$\begingroup$

Since Filling shades between two curves in the plot, add an extra curve that serves as the limit.

Plot[{Max[x + 7, 9 - x^2], x + 7, 9 - x^2}, {x, 0, 1.5}, Filling -> {1 -> {2}}]
|improve this answer
$\endgroup$
3
$\begingroup$ 
Plot[{x + 7, 9 - x^2}, {x, 0, 1.5}, 
 Filling -> {1 -> {{2}, {{Opacity[0.2], Hue[0.67, 0.6, 0.6]}, None}}}]

enter image description here

Update: you can use Automatic instead of {Opacity[0.2], Hue[0.67, 0.6, 0.6]}.

|improve this answer
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.