Using absolute locator coordinates in Manipulate

Question

In this simplified code below, I'd like to display two plots within Manipulate, and use the Locator controltype to set the value of x relative to its position within the first plot only. With the Print[x] command inserted it is obvious that the locator is using the coordinates of the entire graphics plane.

Manipulate[
 Print[x];
 GraphicsRow[{ListLinePlot[{x, {0, 0}}, 
    PlotRange -> {{0, 2}, {0, 2}}], 
   ListLinePlot[{x, {2, 2}}, 
    PlotRange -> {{0, 2}, {0, 2}}]}], {{x, {0, 0}, {2, 2}}, 
  ControlType -> Locator}]

Answer 1

Just replace GraphicsRow to Row!

Manipulate[
 Row@{ListLinePlot[{x, {0, 0}}, PlotRange -> {{0, 2}, {0, 2}}, ImageSize -> 200], 
   ListLinePlot[{x, {2, 2}}, PlotRange -> {{0, 2}, {0, 2}}, ImageSize -> 200]}, 
 {{x, {0, 0}, {2, 2}}, Locator}]

Also instead of ControlType -> Locator you can use just Locator.

P.S. Does anybody know how to choose the second plot?

Answer 2

Using LocatorPane we can do this:

DynamicModule[{pt},
  GraphicsRow[{
    LocatorPane[Dynamic[pt], Dynamic@ListLinePlot[{{0, 0}, pt},
          PlotRange -> {{0, 2}, {0, 2}}]],
    Dynamic@ListLinePlot[{{2, 2}, pt}, PlotRange -> {{0, 2}, {0, 2}}]      
   }]]