# How to solve a system of integral equations?

I have a system of two integral equations

Sin[v] Integrate[
(x[v, z] b Sin[v])/Sqrt[(a^2 Cos[v]^2 + b^2 Sin[v]^2 + z^2)^3],
{v, 0, 2Pi}, {z, -l, l}] == 0

Cos[v] Integrate[
(x[v, z] a Cos[v])/Sqrt[(a^2 Cos[v]^2 + b^2 Sin[v]^2 + z^2)^3],
{v, 0, 2Pi}, {z, -l, l}] == 0


I would like to find a solution x[v,z] of the both equations.

Then I would like to plot 3D graph with axes v,z,x[v,z].

Can anyone help me in finding a solution?

• Cos and Sin are case sensitive cos[x] and sin[x] wont do anything. I updated the code in your post
– ssch
Sep 26, 2013 at 11:01
• I'm confused by the region of integration {z,-z,z}, could you double check this?
– ssch
Sep 26, 2013 at 11:10

There are infinitely many solutions satisfying the system of the equations.
If we set x[v, z] to be constant and add appropriate assumptions the both integrals vanish.
Moreover we could find a few consecutive values of the integrals for e.g. x[v, z] == z^k
and k ∈ {0, 1, 2, ...} putting it in a Table.
Nevertheless we can do much more proving an appropriate theorem:

If x[v, z] doesn't depend on v and it is a polynomial function in z then the both integrals vanish.

To get this result let's check

Resolve[
ForAll[ k, k ∈ Integers && k >= 0,
Integrate[ z^k Cos[v]/Sqrt[(a^2 Cos[v]^2 + b^2 Sin[v]^2 + z^2)^3],
{v, 0, 2 Pi}, {z, -l, l},
Assumptions -> l > 0 && (a | b) ∈ Reals] == 0]]

True


similarly

Resolve[
ForAll[ k, k ∈ Integers && k >= 0,
Integrate[ z^k Sin[v]/Sqrt[(a^2 Cos[v]^2 + b^2 Sin[v]^2 + z^2)^3],
{v, 0, 2 Pi}, {z, -l, l},
Assumptions -> l > 0 && (a | b) ∈ Reals] == 0]]

True


Since integration operator is linear we have proved that for any polynomial p[z] == x[v, z] the both integrals vanish. QED.

Calulation of the integrals if x[v, z] depends on v only is much more involved and we could find its values on a case by case basis. If x[v, z] == v z the system is satisfied under assumptions l > 0 && (a | b) ∈ Reals.

Let's plot a few special cases of given functions

With[{a = 1, b = 2},
GraphicsRow @ Table[
Plot3D[ v z^k Cos[v]/Sqrt[(a^2 Cos[v]^2 + b^2 Sin[v]^2 + z^2)^3],
{v, 0, 2 Pi}, {z, -2, 2}, ClippingStyle -> None], {k, 0, 2}]]