12
$\begingroup$

I have a ragged list

ragged = {{a,b,c,d,e},{x,y,z}}

that I would like to trim (on the right) to be rectangular. The desired result is

{{a,b,c},{x,y,z}}

It seems like this should be a one-word operation but I can't find the one word. So far the best I can do is to PadRight with Null and then delete everything with a Null in it.

Transpose[
 DeleteCases[
  Transpose[
   PadRight[
    ragged,
    Automatic,
    Null
    ]
   ],
  a_ /; MemberQ[a, Null]
  ]
 ]

This seems way too complicated for such a simple operation. What is the simplest way to do this?

Improve this question
$\endgroup$

5 Answers 5

Reset to default
13
$\begingroup$

You are looking for Take. To then make the array rectangular, I would do something like this

Take[ragged, All, Min[Length /@ ragged] ]
Improve this answer
$\endgroup$
2
  • $\begingroup$ How did he fix that without it showing the edit? $\endgroup$
    – Brett Champion
    Mar 20, 2012 at 15:30
  • 1
    $\begingroup$ @BrettChampion I was within the 5 minute window. $\endgroup$
    – rcollyer
    Mar 20, 2012 at 15:31
14
$\begingroup$

What about:

ragged[[All, 1 ;; Min[Length /@ ragged]]]

{{a, b, c}, {x, y, z}}

Improve this answer
$\endgroup$
2
  • 2
    $\begingroup$ Very nice ! You can even drop 1 and write ragged[[All, ;; Min[Length /@ ragged]]] $\endgroup$
    – Artes
    Mar 20, 2012 at 15:41
  • 1
    $\begingroup$ Yep! Good for the oneliner contest but potentially dangerous for sloppy readers (i.e. me). $\endgroup$
    – Yves Klett
    Mar 20, 2012 at 15:45
9
$\begingroup$

You could do something like

PadRight[ragged, {Automatic, Min[Length /@ ragged]}]
Improve this answer
$\endgroup$
2
  • $\begingroup$ Automatic apparently doesn't work on v7. $\endgroup$
    – Mr.Wizard
    Mar 20, 2012 at 15:31
  • 3
    $\begingroup$ +1 for showing that PadRight can remove elements. I didn't know that. $\endgroup$
    – ArgentoSapiens
    Mar 20, 2012 at 16:49
7
$\begingroup$

Here is a timing comparison of the methods presented. I had to modify Heike's code because it did not work on version 7.

SetAttributes[timeAvg, HoldFirst]

timeAvg[func_] := 
 Do[If[# > 0.3, Return[#/5^i]] & @@ Timing@Do[func, {5^i}], {i, 0, 15}]

ragged = RandomReal[99, #] & /@ RandomInteger[{25, 100}, 5000];

PadRight[ragged, {Length@ragged, Min[Length /@ ragged]}]; // timeAvg

ragged[[All, ;; Min[Length /@ ragged]]]; // timeAvg

Take[ragged, All, Min[Length /@ ragged]]; // timeAvg

0.02808

0.002864

0.002744

ragged = RandomReal[99, #] & /@ RandomInteger[{2500, 5000}, 50];

PadRight[ragged, {Length@ragged, Min[Length /@ ragged]}]; // timeAvg

ragged[[All, ;; Min[Length /@ ragged]]]; // timeAvg

Take[ragged, All, Min[Length /@ ragged]]; // timeAvg

0.01688

0.00009184

0.000088896

rcollyer wins!

Improve this answer
$\endgroup$
8
  • $\begingroup$ I modified my answer to what you proposed when I was fixed the "Trim" issue. $\endgroup$
    – rcollyer
    Mar 20, 2012 at 15:43
  • $\begingroup$ Darn. You win again, Mr. Wizard (or rcollyer, I a afraid of a grandfather paradox). $\endgroup$
    – Yves Klett
    Mar 20, 2012 at 15:49
  • $\begingroup$ @rcollyer corrected $\endgroup$
    – Mr.Wizard
    Mar 20, 2012 at 15:49
  • 2
    $\begingroup$ @YvesKlett well, we've already established that I'm part of the Mr.Wizard collective. $\endgroup$
    – rcollyer
    Mar 20, 2012 at 15:58
  • 1
    $\begingroup$ Great. Now I´ll have to spend the rest of the day to search for some far-fetched example to demonstrate Parts superiority. S´ not like I have a job or something. No borg, me! $\endgroup$
    – Yves Klett
    Mar 20, 2012 at 15:59
3
$\begingroup$

In version 10 the package GeneralUtilites contains the functions TrimLeft and TrimRight:

x = {{1, 2, 3}, {1, 2, 3, 4}, {1, 2}};

Needs["GeneralUtilities`"]

TrimLeft[x]
TrimRight[x]

{{2, 3}, {3, 4}, {1, 2}}

{{1, 2}, {1, 2}, {1, 2}}

Burdened with the additional argument testing overhead of a packaged function these are not quite as fast as the raw methods posted earlier but they are sufficient. The core of each is akin to Yves Klett's answer:

lists[[All, -Min[Length /@ lists] ;; All]]

lists[[All, 1 ;; Min[Length /@ lists]]]
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.