# Labeling points of intersection between plots

There are several answers where Mathematica used mesh points to show graphically where curve intersections exist.

Is there a way to include the actual point values (maybe they are simply labeled as a, b, c ...) and then the actual value is displayed on the right of the graphic?

Here is the specific example I am working.

Plot[{Cos[x],(1/2)^x},{x,-1,11},
PlotPoints->84,
MaxRecursion->9,
MeshFunctions->{Cos[#1]-(1/2)^#1&},
Mesh->{{0}},
MeshStyle->Directive[Red,PointSize[Large]]]

• You can put Graphics[Text[#, #] & /@ coords] to the Show or just Text part to the Epilog.
– Kuba
Sep 11 '13 at 6:09
• @Kuba ... and with small offset on the coordinate part of Text, it's positioned next to the point itself, not on top of it. Sep 11 '13 at 6:41
• lines meet at solutions of two lines equations..may be you want to find solutions first and them use Text as suggested to get only relevant info. Sep 11 '13 at 6:55

opts = {ImageSize -> 500, PlotRange -> {{-5, 15}, All}, PlotPoints -> 84,
MaxRecursion -> 9, MeshFunctions -> {Cos[#1] - (1/2)^#1 &}, Mesh -> {{0}},
MeshStyle -> {Directive[Red, PointSize[Large]]}};


You may be interested in the fact that Mesh solution is good for visulatisation purposes but it seems that coordinates given with this method are only approximation.

Also there are double points, one for each curve and each aproximation is independent what may result in different coordinates.

Taking your example let's label those points:

(Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, Evaluate@opts] // Normal
) /. Point[x_] :> ({Point@x,
Text[Style[NumberForm[#, {Infinity, 2}], Bold, Black, 15] &@x
, x + {0, .5 - RandomReal[]/2}]})


It basically replaces points with points + labels. Labels are with random offset so you can see what I was reffering to. Normal is in order to get rid of the GraphicsComplex.

As you can see, the mesh point near $y$ axis has different coordinates :)

Edit So at the end I would use NSolve based solution like in the first link you've provided:

After all I forgot you asked for the legend next to the plot :)

points = {x, Cos[x]} /. NSolve[Cos[x] == (1/2)^x && -1 < x < 11, x];
names = FromCharacterCode /@ (Range[Length@points]+96)

{"a", "b", "c", "d", "e"}

 Row[{
Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, Evaluate@opts,
Epilog -> (Text[Style[#, 20], #2 + {0, .2}] & @@@ Transpose[{names, points}])
]
,
}]


• I know it's an old question / answer, but I need to understand why, in your first solution, there are double coordinates at each intersection point? Sep 8 '15 at 15:56
• @Conrad I'm not sure but it seems it is what I;ve said. Mesh points are generated separately for each curve, maybe to be sure that everything is covered if one curve is problematic or something.
– Kuba
Sep 8 '15 at 18:42
• Ok, so your second solution (using NSolve) is preferable. But how would you manage intersection with several curves (Cos[x], Sin[x], Tan[x])? The syntax would become much more complex? Sep 9 '15 at 12:49

## DisplayFunction

Using a custom DisplayFunction that injects labels as locators for the mesh points:

ClearAll[displayF]
displayF[offset_: {20, 20}] := (Normal[#] /.
p : {__Point} :> (Point /@ DeleteDuplicates[p[[All, 1]],
Round[#, .1] == Round[#2, .1] &]) /.
Point[x_] :> {Point[x], Locator[Offset[offset, x],
Framed[Column @ Round[x, .0001], FrameStyle -> None,
Background -> Opacity[.5, Yellow]]]} &);


Examples:

Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, PlotPoints -> 84,
MaxRecursion -> 9, MeshFunctions -> {Cos[#1] - (1/2)^#1 &},
Mesh -> {{0}}, MeshStyle -> Directive[Red, PointSize[Large]],
PlotRangeClipping -> False, ImageSize -> 600, ImagePadding -> 70,
DisplayFunction -> displayF[]]


Plot[{x Sin[x], x Cos[x]}, {x, -1, 11}, PlotPoints -> 150,
MaxRecursion -> 9, MeshFunctions -> {# Sin[#] - # Cos[#] &},
Mesh -> {{0}}, MeshStyle -> Directive[Red, PointSize[Large]],
PlotRangeClipping -> False, ImageSize -> 600, ImagePadding -> 70,
DisplayFunction -> displayF[]]


Perhaps ugly but may achieve what you want:

p = Plot[{Cos[x], (1/2)^x}, {x, -1, 11}, PlotPoints -> 84,
MaxRecursion -> 9, MeshFunctions -> {Cos[#1] - (1/2)^#1 &},
Mesh -> {{0}}, MeshStyle -> Directive[Red, PointSize[Large]],
ImageSize -> 300]


Extract intersection points (which as described are approximates with duplicates):

intp = Extract[p[[1, 1]], List /@ p[[1, 2, 2, 1, 2, 1]]]


"Clean" and sort (by removing "same" x value) and create labels:

sorted = Chop[#, 10^(-8)] & /@
SortBy[DeleteDuplicates[intp,
Chop[#1[[1]] - #2[[1]], 10^(-4)] == 0 &], #[[1]] &]
labels = FromCharacterCode /@ (96 + Range[Length[sorted]])


Display:

Row[{
Show[p,
Graphics[
Text[Style[#1, 16], #2 + {0.1, 0.2}] &, {labels, sorted}]]],
Grid[Transpose[{labels, sorted}], Frame -> True]
}]


yields:

• I'm not sure if the way that you are getting intp is safe enough to be used always, maybe you can use something like: Cases[p, GraphicsComplex[x_, ___] :> Part[x, First@Cases[p, Point[z_] :> z, \[Infinity]]], \[Infinity]]
– Kuba
Sep 11 '13 at 8:30
• @Kuba Thank you, I agree entirely that this is not general and just an interrogation and dissection of the GraphicsComplex. I just wished to show that you can access the points. I regard this as ugly but hoped that comments such as yours would arise. Thank you for the more general method...I have learned something. Sep 11 '13 at 8:39
• I'm glad you find it useful. :)
– Kuba
Sep 11 '13 at 8:43