How to capitalize the first letter of each word in a string

Question

The following examples only work for the first character of the whole string, but not of words.

s = "words are lowercase";
StringJoin[MapAt[ToUpperCase, Characters[s], 1]]   (* ==> "Words are lowercase" *)
StringReplacePart[#, ToUpperCase[StringTake[#, 1]], 1]&@s  (* ==> "Words are lowercase" *)

Is there any method along these lines to produce correct title case strings of the form:

"Words Are Lowercase"

Answer 1

From the documentation, though IMHO not easy to find:

StringReplace["this is a test", WordBoundary ~~ x_ :> ToUpperCase[x]]

"This Is A Test"

---

István Zachar highlighted a problem with WordBoundary that I'm still trying to understand. Nevertheless it seems that one can use:

strAcc = "árv ízt űr őt ük örf úr óg ép";

StringReplace[strAcc, z : (StartOfString | WhitespaceCharacter ~~ _) :> ToUpperCase[z]]

"Árv Ízt Űr Őt Ük Örf Úr Óg Ép"

It appears that the PCRE library at least as used by Mathematica does not recognize certain characters as letters. A few examples:

StringReplace[strAcc, z : RegularExpression["(?:\\A|\\s)."] :> ToUpperCase[z]]
StringReplace[strAcc, z : RegularExpression["\\b."] :> ToUpperCase[z]]

"Árv Ízt Űr Őt Ük Örf Úr Óg Ép"

"Árv Ízt űR őT Ük Örf Úr Óg Ép"  (* note odd handling *)

StringCases["abcőű", RegularExpression["\\w"]]

{"a", "b", "c"}                  (* ő and ű missing *)

Answer 2

Actually, WordBoundary won't always work correctly (see this thread):

str = "the lazy dog jumped over the quick brown fox.";
strAcc = "árv ízt űr őt ük örf úr óg ép";

StringReplace[str, WordBoundary ~~ x_ :> ToUpperCase[x]]
StringReplace[strAcc, WordBoundary ~~ x_ :> ToUpperCase[x]]

"The Lazy Dog Jumped Over The Quick Brown Fox."

"Árv Ízt űR őT Ük Örf Úr Óg Ép"   (* note ű,ő instead of Ű,Ő *)

Use instead this custom made toTitleCase:

toTitleCase[str__] := StringJoin@Riffle[ToUpperCase@StringTake[#, 1] <> 
       ToLowerCase@StringTake[#, {2, -1}] & /@ StringSplit@StringJoin@str, " "];

toTitleCase[str]
toTitleCase[strAcc]

"The Lazy Dog Jumped On The Quick Brown Fox."

"Árv Ízt Űr Őt Ük Örf Úr Óg Ép"

---

In version 10.1, this is built in as ToTitleCase (if I recall correctly, it was an experimental function; documentation is no longer accessible on the net). This version removes all non-alphanumeric characters from the string; I assume this is a bug.

ToTitleCase[str]
ToTitleCase[strAcc]

"The Lazy Dog Jumped On The Quick Brown Fox"

"Árv Ízt Űr Őt Ük Örf Úr Óg Ép"

---

ToTitleCase has an eventful development history: in version 11, it is removed from among the built-ins, but is still acccessible from the "GeneralUtilities`" context. It does not remove non-alphanumeric characters anymore from the string.

GeneralUtilities`ToTitleCase[str]
GeneralUtilities`ToTitleCase[strAcc]

"The Lazy Dog Jumped Over the Quick Brown Fox."

"Árv Ízt Űr Őt Ük Örf Úr Óg Ép"

Answer 3

While I endorse Mr.Wizard's pattern matching solution and I've given Istvàn +1 I would also like to submit this function which is meant to not rely on string patterns and be as readable as possible:

toTitleCase[str_] := StringJoin[
  MapAt[
   ToUpperCase, Characters[str], 
   Position[Characters[" " <> StringTrim@str], " "]
   ]
  ]

toTitleCase["the lazy dog jumped over the quick brown fox"]

"The Lazy Dog Jumped Over The Quick Brown Fox"

Answer 4

Starting in M11.2 or M11.3 you can use Capitalize with "TitleCase" as the second argument:

Capitalize["words are lowercase", "TitleCase"]

"Words Are Lowercase"

Answer 5

I just came across this problem with strings containing parentheses and acronyms, and the above solutions didn't work correctly for me. This is the solution I came up with:

toTitleCase[str_] := StringReplace[
    ToUpperCase@str, (f_?LetterQ ~~ rest:(LetterCharacter..)) :> 
    f <> ToLowerCase[rest]
];

toTitleCase["the (LAZY) d.O.G."]

"The (Lazy) D.O.G."

Answer 6

rule = RegularExpression["\\b([[:lower:]])"] :> ToUpperCase["$1"];
StringReplace[s, rule]

Answer 7

All of the answers posted has a wrong result when applied to this string :

"hoSsEiN HAdi" -> "HoSsEiN HAdi"

But you can use the below code to ensure that all of the subsequent letters has been changed to LowerCase:

StringJoin @ StringCases["aA AA aa Aa 1a 2a a2 A2", WordBoundary~~Shortest[x_] ~~ Shortest[y___] ~~ WordBoundary :> ToUpperCase[x] <> ToLowerCase[y]]

This gives the following result :

"Aa Aa Aa Aa 1a 2a A2 A2"