Exp of big negative numbers [duplicate]

Question

I noticed that Exp have a strange behaviour with big negative numbers

Exp[-Range[1, 700, 0.001]] // Developer`PackedArrayQ // AbsoluteTiming
Exp[-Range[1, 800, 0.001]] // Developer`PackedArrayQ // AbsoluteTiming

{0.014877, True}

{1.551377, False}

I understand than Exp[-800.0] is less than $MinMachineNumber, so I expected that the answer will be 0.0, but it is 3.668*10^-348 wich is not a machine number.

MachineNumberQ@Exp[-800.0]

False

What is the best way to work with these numbers? N@Exp do nothing.

My current solution is

NExp = Exp@Clip[#, {-100.0, 100.0}] &;

NExp[-Range[1, 800, 0.001]] // Developer`PackedArrayQ // AbsoluteTiming

{0.016354, True}

Moreover, I notice that Exp works fine with complex numbers (only in v9)

Exp[0.0 I - Range[1, 700, 0.001]] // Developer`PackedArrayQ // AbsoluteTiming
Exp[0.0 I - Range[1, 800, 0.001]] // Developer`PackedArrayQ // AbsoluteTiming

{0.049367, True}

{0.066757, True}

Edit:

I saw the answer with suggestion of compilation but for some reason it was removed. It is not very fast solution but it works. So I post it here

NExp = Compile[{{x, _Real}}, Exp[x], RuntimeAttributes -> {Listable}];

NExp[-Range[1, 800, 0.001]]) // Developer`PackedArrayQ // AbsoluteTiming

{0.114772, True}

Answer 1

Will something like this work?

SetPrecision[Chop[N@#], MachinePrecision] & /@ Exp[-Range[1, 800]] //
   Developer`ToPackedArray // Developer`PackedArrayQ // AbsoluteTiming

{0.004003, True}

The number has to first be converted to a numerical form with N or Chop won't do anything to it. Even if the number is large enough it isn't guaranteed to be converted to a machine precision number so we force that by calling SetPrecision. Conversion to a packed array isn't guaranteed either, so we have to call ToPackedArray. But, ToPackedArray won't convert a list if there will be a precision loss.

For a single value the following returns True.

MachineNumberQ@SetPrecision[Chop[N@Exp[-800]], MachinePrecision]

True