Manipulate using a variable defined outside of the manipulate function [duplicate]

Question

I want to do something like this:

expr := x^e;
Manipulate[Plot[expr, {x, 0, 4}], {e, 1, 3}]

But the plot shows up empty.

Yes, it works if I do:

expr[x_,e_] := x^e;
Manipulate[Plot[expr[x,e], {x, 0, 4}], {e, 1, 3}]

But I don't want to do that. Why? Because the function I'm actually working with has about a dozen variables. I want to be able define my function just as as expression (that I use in many places throughout my notebook, in addition to this particular Manipulate) so that I don't have to bother with remembering the order in which I defined the dozen or so variables that comprise the function definition. This way I can substitute values into my function using ReplaceAll as I see fit.

My approach has been working fine as I continue to shape this function, but using Manipulate becomes very cumbersome. I want to manipulate several of these variables without having to worry about typing a whole lot of code. Is there a way I can keep the definition of my function as a simple Set or SetDelayed (without the pattern matching) but change something about my Manipulate expression to make the Manipulate function actually manipulate symbols that are not do not explicitly occur within the Manipulate expression? Thanks!

Answer 1

The control variable must appear in the Manipulate expression to be tracked. In this case it is e

Make expr a true function which is done by passing it all the arguments it needs, and then call it from inside Manipulate expression:

expr[e_, x_] := x^e;
Manipulate[Plot[expr[e, x], {x, 0, 4}],
 {e, 1, 3}]

Now you can use your function outside of Manipulate, and have it used by Manipulate as well, which is what your goal was.

Second option

But if you really insist in making e appear outside and still use the expression from inside Manipulate, then use the LocalizeVariables -> False option

expr := x^e;
Manipulate[
 e;
 Plot[expr, {x, 0, 4}],
 {e, 1, 3},
 LocalizeVariables -> False
 ]

But notice that e was added in the Manipulate expression, just so that it is tracked.

Answer 2

The reason why this does not work is because the variables in a Manipulate do not actually have the name you see displayed - they have scoped ones. For instance, Manipulate[Hold[x] // Print, {x, 1, 3}]; prints Hold[FE'x$$9]. You can use ReplaceAll to transfer from the actual name of the variables to the manipulate placeholder:

expr := x^e;
Manipulate[Plot[expr /. e -> eprime, {x, 0, 4}], {eprime, 1, 3}]

Answer 3

Here's what I ended up using:

expr := x^e;
Manipulate[Plot[#, {x, 0, 4}], {e, 1, 3}] &@expr

Which works great and doesn't require extra function arguments or replacement rules.