Alternate parameterization of a line

Question

There are several ways to specify a line. In Mathematica's graphics, it is done by specifying two points and then connecting the points with the Line command. But it is sometimes desirable to parameterize a line, and the most familiar way is the form $y = m x + b$ where $m$ is the slope and $b$ is the offset. This parameterization is particularly awkward for near-vertical lines (where the slope becomes near infinite and numerically sensitive). An alternative is the $(\rho, \theta)$ parameterization which specifies the line as an angle $\theta$ and a distance $\rho$ from the origin, as shown in the theory section of this wikipedia article. The gist is that the line consists of all points $x$ and $y$ for which $\rho = x \cos(\theta) + y \sin(\theta)$, essentially a conversion to polar coordinates.

Here is a function which takes a pair of points {p1, p2} as input in the form {{x1,y1},{x2,y2}} and outputs the corresponding $\rho$ and $\theta$:

linePolar[{p1_, p2_}] := Module[{},
    {rx, ry} = Rationalize[p1]; {sx, sy} = Rationalize[p2];
    sol = Solve[{rx Cos[t] + ry Sin[t] == rho, 
             sx Cos[t] + sy Sin[t] == rho}, {rho, t}] // N;
    First[Select[{rho, t} //. sol //. C[1] -> 0, #[[1]] >= 0 &]]];

For example:

linePolar[{{0, -1}, {-1, 0}}]
{0.707107, -2.35619}

which shows that the line connecting the two points is Sqrt[2]/2 away from the origin at an angle of -135 degrees. The almost vertical line

linePolar[{{1, -1}, {1.1, 1}}]
{1.04869, -0.0499584}

has slope near zero, and the answer appears to be nicely behaved numerically as the line crosses vertical.

I have two questions. First, it bothers me that the function is essentially re-solving the system of equations each time it is called, and this must be inefficient. Is there a nice way to make it only do the solution once? Second, I would like to have an "inverse" for this function -- something that would take a pair of $(\rho, \theta)$ values and allow it to be plotted. This would be useful because many subsequent calculations need to occur in the $(\rho, \theta)$ space, and it would be good to be able to visualize this by plotting.

Answer 1

The Cross product is very useful here. It can be used with 3D vectors to get the perpendicular distance of a line to the origin, but it also works with a 2D vector as an easy way to specify its perpendicular:

This function returns the radial distance $\rho$ and the angle $\theta$ as in the question, but doesn't require resolving the coordinates of the given points explicitly:

lineToPolar[{p1_, p2_}] := 
 {
  Abs[#], ArcTan @@ Cross[Sign[#] (p2 - p1)]} &@
  Last[Apply[Cross, PadRight[#, 3] & /@ {p1, Normalize[p1 - p2]}]]    

lineToPolar[{{0, -1}, {-1, 0}}]

(* ==> {1/Sqrt[2], -((3 Pi)/4)} *)

Simplify[
 lineToPolar[{{x, y}, {u, v}}], {x, y, u, v} ∈ Reals]

$$\begin{array}{c}\{\frac{\left| v x-u y\right|}{\sqrt{(u-x)^2+(v-y)^2}},\\\tan^{-1}\left(\frac{(v-y) \text{sgn}(v x-u y)}{\sqrt{\text{sgn}\left((u-x)^2+(v-y)^2\right)}},\frac{(u-x) \text{sgn}(u y-v x)}{\sqrt{\text{sgn}\left((u-x)^2+(v-y)^2\right)}}\right)\}\end{array}$$

This is the general formula for the polar representation. You could use this directly to define the conversion function if desired.

To optimize the conversion function some more, the component form of the given vectors could be used together with this form, where the Sign function has been turned into a case distinction:

FullSimplify[
  lineToPolar[{{x, y}, {u, v}}], {x, y, u, v} ∈ Reals] /. 
 Indeterminate -> 0

$$\{\frac{\left| v x-u y\right| }{\sqrt{(u-x)^2+(v-y)^2}}, \begin{cases} 0 & v x=u y \\ \tan ^{-1}(v-y,x-u) & u y<v x \\ \tan ^{-1}(y-v,u-x) & \text{True} \\ \end{cases} \}$$

Edit:

In an earlier version, the parameter $\rho$ was allowed to be negative if the order of p1 and p2 was reversed. That means $\rho$ is the 2D impact parameter of the line, but for a real polar coordinate you may want to require $\rho>0$. In the above code, I make sure that when the impact parameter is negative we exchange the order of p1 and p2 to get back to a positive $\rho$.

End edit

The inverse is even simpler:

Clear[ρ, θ]; 
lineFromPolar[ρ_, θ_] = 
 Function[{t}, {t, ρ}.#] &[RotationMatrix[Pi/2 - θ]]

With[{ρ = 1/2, θ = 3 Pi/4},
 ParametricPlot[lineFromPolar[ρ, θ][t], {t, -10, 10}]
 ]

Here I used the fact that the offset from the origin is specified by a vector perpendicular to the line, of length $\rho$. This required orthogonality is provided automatically by the rows of RotationMatrix.

Answer 2

Evaluating lineToPolar[{{1,-1},{1.1,1}}] gives a negative rho, and an angle t differing by $\pi$ from the OP example. Incorporating a simple Abs[rho] and keeping the same angle t gives a different line than I think is required. I used

lineToPolarAlt[{{x1_, y1_}, {x2_, y2_}}] :=
   With[{numerator = -y1 x2 + x1 y2},
        {Abs[(numerator)/Norm[{x1, y1} - {x2, y2}]], 
         If[numerator >= 0, Arg[ I x1 - y1 - I x2 + y2], 
                            Arg[-I x1 + y1 + I x2 - y2]]}]

to check the two different cases.