Can Mathematica differentiate summation notation with respect to an indexed variable?

Question

My question is whether Mathematica can represent an expression such as:

$$y_i = \sum_{j=1}^N a_{ij} x_j$$

symbolically as a sum over indefinite bounds (unknown $N$), and differentiate it with respect to an indexed variable such as $a_{ik}$. The answer in this case should be $\partial y_i / \partial a_{ik} = x_k$.

For a more involved example, if we have

$$f_k = x_k \sum_i \sum_j g(a_{ij}, x_j)$$

then

$$\partial f_k / \partial x_n = \delta_{nk} \sum_i \sum_j g(a_{ij}, x_j) + x_k \sum_i \sum_j D_2 g(a_{ij}, x_j) \delta_{nj}$$ $$=\delta_{nk} \sum_i \sum_j g(a_{ij}, x_j) + x_k \sum_i D_2 g(a_{in}, x_n)$$ where $\delta$ is the Kronecker delta and $D_2 g$ is the derivative of $g$ with respect to its second parameter.

Can Mathematica do both of these examples as stated?

---

With advice from a user on wolfram community, I tried:

Assuming[
 1 <= k <= z && k ∈ Integers
&& 1 <= n <= z && n ∈ Integers,
 ff = D[x[k] * Sum[Sum[g[a[i, j],x[j]], {j, 1, z}], {i, 1, z}], x[n]]
 ]

But this gives the wrong answer: Sum[Derivative[0, 1][g][a[i, n], x[n]], {i, 1, z}]*x[k]. It omits the other term in the answer.

Another user from Wolfram Community suggested trying

Assuming[
 1 <= k <= z && k ∈ Integers
&& 1 <= n <= z && n ∈ Integers,
 ff = D[If[n == k, x[n],x[k]]  * Sum[Sum[g[a[i, j],x[j]], {j, 1, z}], {i, 1, z}], x[n]]
 ]

which gives the result

If[k == n, 1, 0]*Sum[Sum[g[a[i, j], x[j]], {j, 1, z}], {i, 1, z}] + 
  If[k == n, x[n], x[k]]*Sum[Derivative[0, 1][g][a[i, n], x[n]], {i, 1, z}] 

This is technically correct but there are two problems. First, it doesn't convert the first If[] expression to a KroneckerDelta, and it doesn't eliminate the second If[] expression. It doesn't seem to be able to simplify If[] expressions much at all; in other testing I find it will leave If[expr, 0, 0] in that form without simplifying to 0. The second problem is that I need to add those If[] expressions for every variable, and if I have multiple "free" indices (in more complex examples than shown here) that's a lot of cases to handle, requiring me to test for every variable whether or not each of its indices is equal to any of the other indices in the expression. The expression gets so complicated that I'd be better off doing it by hand from the start than manually rewriting and simplifying the Mathematica output.

Answer 1

OK, though I've done this many times, given that coding this in Mathematica requires one to have a good enough understanding for the core language, let me do a favor:

Clear[myD, mySum]

myD[a_ b_, c_] := a myD[b, c] + b myD[a, c]
(* Add the rule for addition just in case: *)
myD[a_ + b_, c_] := myD[a, c] + myD[b, c]

myD[mySum[a_, b__], x_] := mySum[myD[a, x], b]

myD[(h_ /; Context[h] =!= "System`")[a__], x_] := 
 With[{l = Length@{a}}, 
  Total@MapThread[
    Derivative[Sequence @@ #][h][a] myD[#2, x] &, {IdentityMatrix@
      l, {a}}]]

myD[Subscript[a_, i___, j1_, k___], Subscript[a_, i___, j2_, k___]] :=
  KroneckerDelta[j1, j2]

myD[Subscript[a_, __], Subscript[b_, __]] := 0

mySum[KroneckerDelta@OrderlessPatternSequence[i_, j_] expr_, jL___, 
  j_, jR___] := mySum[expr /. j -> i, jL, jR]

mySum[a_] := a

MakeBoxes[mySum[a__], fmt_] ^:= 
 With[{arg = MakeBoxes[#, fmt] & /@ {a}}, 
  With[{funcbody = 
     MakeBoxes[Sum[a], fmt] /. 
      Thread[arg -> (Slot /@ Range@Length@{a})]}, 
   TemplateBox[arg, "mySum", DisplayFunction -> (funcbody &)]]]

Usage:

myD[mySum[Subscript[a, i, j] Subscript[x, j], j], Subscript[a, i, k]]

myD[Subscript[x, k] mySum[g[Subscript[a, i, j], 
                            Subscript[x, j]], i, j], Subscript[x, n]]

You can press Ctrl+Shift+t to transform the output to TraditionalForm, and Ctrl+Shift+n to transform the output to StandardForm.

Answer 2

By design of Mathematica the D operator differentiates an expression wrt to symbols or expressions, that are identifiable as patterns. So you get

 Subscript[f,j] = Sum[Subscript[a,j,k] x^k,{k,1,n}  
        (*never use N* or other capital letter symbols*)
 D[Subscript[f,j],Subscript[a,p,q]]
 0

for any values of p,q except j,k, simply because the pattern is not present in f. But if you differentiate wrt to the actual pattern and setting assumptions accordingly

Assuming[j \[Element] PositiveIntegers, 
     D[Subscript[f, j], Subscript[a, j, k]]] 

$$\begin{array}{cc} \{ & \begin{array}{cc} x^k & j\geq 1\land j-n\leq 0 \\ 0 & \text{True} \\ \end{array} \\ \end{array}$$

In effect this is use of Einstein's ingenious notation shortcut: working with the symbolic kernels of multilinear constructs like sums, integrals of tensor products and linear forms.