Copying an image from the clipboard, modifying it and returning it to the clipboard

Question

I have a Mathematica script to help me copy images from PDFs and then make the (presumably white or nearly white) background transparent. Typically, I am looking at the PDF in Adobe Acrobat and I use the snapshot tool to copy the image to Microsoft Window's clipboard. Then I paste the image into mathematica and assign it the name q. Where I typed {IMAGE} below is where I paste the image into the code:

q = {IMAGE};
p = ColorNegate[Binarize[ImageApply[Min, q], 0.99]];
s = SetAlphaChannel[q, p];
Export["img.png", s];

I run the code and I get a PNG with a transparent background and then I can insert the png with the transparent background into OneNote.

The point of doing this is images with a transparent background are easier to arrange since the don't obscure the other texts. This makes it a snap to place graphs and equations in my notes.

I would like to make this even easier by enhancing my script. This is why I am asking for help. My goals are:

1. Is there some Mathematica command I can use to copy the image from the clipboard automatically without having to manually paste it.

2. Is there a way to get Mathematica to place the image back into the clipboard with a transparent background, thus cutting out the step of using a file.

What I have found is if I use a command like CopyToClipboard[s], it doesn't work.

1. Are there any other enhancements that would make the whole process more automated?

(A side note: it's been a while since I wrote this code, but if I remember correctly, I convert the image to black and white, figure out the background then use the pixels that were designated as background to figure out which pixels to set as transparent in the original image.)

Answer 1

Here are two functions that'll do what you need.

putClipboardImage[img_Image] := Module[{nb},
  nb = CreateDocument[{}, Visible -> False, WindowSelected -> False];
  NotebookWrite[nb, 
   Cell[BoxData@ToBoxes@Image[img, Magnification -> 1]]];
  SelectionMove[nb, All, CellContents];
  FrontEndTokenExecute[nb, "CopySpecial", "MGF"];
  NotebookClose[nb]
  ]

getClipboardImage[] := Module[{tag},
  Catch[NotebookGet@ClipboardNotebook[] /. 
    r_RasterBox :> 
     Block[{}, 
      Throw[Image[First[r], "Byte", ColorSpace -> "RGB"], tag] /; 
       True];
   $Failed, tag]
  ]

Warning: if the image is very small, this method will pad it with some wide pixels. It is copying the cell contents, not the image itself. If the image is small than the cell height, it'll get padded.

Copying

The reason the image can't be pasted to every program when using CopyToClipboard is that it is placed onto the clipboard as a metafile (as well as a Mathematica expression), but not as a bitmap.

My function works by writing the image into a new hidden notebook, then invoking the Edit -> Copy As -> Bitmap command programmatically, to ensure that the image is placed on the clipboard as a bitmap. This works on Windows, but on OS X it's probably necessary to change MGF to something else, as the same command is not available (try PDF). On Linux this functionality is simply not available.

Pasting

Pasting works by accessing the special object ClipboardNotebook[] and reading its contents. The unusual looking ReplaceAll - Throw - Catch construct is just a performance optimization to avoid unpacking the array representing the image data.

I used the same techniques in the image uploader palette.