Clear and Unset doesn't free memory

Question

Example: Try this example only if you have > 4G ram

d = 2000; 
f[x_, y_, d_] = 
     Sum[Subscript[a, i, j]*x^i*y^j, 
       {i, 0, d - 1}, {j, 0, d - i}];

Then

Clear[f]

or

f[x_, y_, d_] =.

You will see that the memory usage is not reduced after calling Clear or using Unset.

Question: How to free the memory when I don't need a function anymore which is already evaluated?

Edit: I look at the memory usage in taskmgr under Windows OS. As the answers report that the memory is indeed reduce by using MemoryInUse to check it.

Answer 1

In version 7 I cannot confirm what you report. With my default of $HistoryLength = 3 I see:

d = 2000;
f[x_, y_, d_] = Sum[Subscript[a, i, j]*x^i*y^j, {i, 0, d - 1}, {j, 0, d - i}];

MemoryInUse[]

Clear[f]
MemoryInUse[]

774871544

454831808

With $HistoryLength = 0 as suggested by Ruslan:

774868608

14955736

---

Michael suggested using Block to set $HistoryLength but this doesn't actually work. Instead his code functions by a different method: it never assigns the output of the Sum to Out[], because that line returns MemoryInUse[]. The same thing can be done with with CompoundExpression:

d = 2000;
f[x_, y_, d_] = Sum[Subscript[a, i, j]*x^i*y^j, {i, 0, d - 1}, {j, 0, d - i}]; 1;
MemoryInUse[]
Clear[f];
MemoryInUse[]

774872048

14957200

The key is:

expr; 1;

Now the value set for Out[] is 1 rather than expr.

You may wonder why expr; assigns anything to Out[] -- this is intended and useful behavior because you often want to suppress the output of a line and reference it in the line below using %. expr; is short for CompoundExpression[expr, Null], which is recognized and handled to set Out[] to the evaluated expr instead of Null.