Is there another method to prove whether a triangle that meets these given conditions actually exists?

Question

Given the information about the isosceles triangle：

In the isosceles triangle ABC, where AB = BC = 5, and BD is perpendicular to AC at D, the angle bisector AO of angle A intersects BD at O. Given that BO = 2 and AO = 4, find the lengths of OD and AC.

Establish a rectangular coordinate system with the midpoint of base AC as the origin, and the line where AC is located as the x-axis.

{a = {-x, 0}, c = {x, 0}, b = {0, h}, o = {0, h - 2}}
Reduce[{Norm[a - b] == 5 == Norm[b - c], Norm[b - o] == 2, 
  Norm[a - o] == 4, t == h - 2, x/5 == (h - 2)/2, h > 0}]

Answer 1

The three given conditions that AO bisects the angle at A, BO = 2 and AO = 4 are incompatible with the other hypotheses. Any two of these three conditions are compatible with the others, but, naturally, lead to different solutions.

Let's use GeometricScene to study these assertions. (Unfortunately, GeometricScene is not available in the cloud version 14.1.) First we write our hypotheses and our three givens using the guidelines at GeometricScene.

Hypotheses and Givens

ClearAll["Global`*"]

hyp = {Triangle[{a, b, c}],
     EuclideanDistance[a, b] == EuclideanDistance[b, c] == 5,  
     GeometricAssertion[{a, d, c}, "Collinear"],
     GeometricAssertion[{Line[{b, d}], Line[{a, c}]}, "Perpendicular"],
     GeometricAssertion[{b, d, o}, "Collinear"]};

givens = {EuclideanDistance[b, o] == 2, EuclideanDistance[a, o] == 4,
   PlanarAngle[{b, a, o}] == PlanarAngle[{o, a, c}]};

First Scene

The first scene will use the two distance conditions and ignore the angle bisector condition. We define the scene and calculate the distances OD and AC like this

s1 = GeometricScene[{a, b, c, d, o}, {hyp, givens[[{1, 2}]]}];

GeometricSolveValues[s1,
 {EuclideanDistance[o, d],
  EuclideanDistance[a, c]}]

$\left( \begin{array}{cc} \frac{5}{4} & \frac{\sqrt{231}}{2} \\ \end{array} \right)$

If AO was the bisector of angle BAC, the two angles BAO and OAC would be equal. The angles are calculated like this:

GeometricSolveValues[s1, {
  PlanarAngle[{b, a, o}], PlanarAngle[{o, a, c}]}]

$\left( \begin{array}{cc} \cos ^{-1}\left(\frac{37}{40}\right) & \cos ^{-1}\left(\frac{\sqrt{231}}{16}\right) \\ \end{array} \right)$

We see that the two angle are not equal, so the bisector condition is incompatible with the two distance conditions.

Second Scene

The second scene uses the first distance condition, BO=2, and the angle bisector condition to calculate the unknown distance OD and AC.

s2 = GeometricScene[{a, b, c, d, o}, {hyp, givens[[{1, 3}]]}];
 GeometricSolveValues[s,
 {EuclideanDistance[o, d],
  EuclideanDistance[a, c]}]

(* {{1.44828, 7.24138}} *)

The two half-angles at A can be calculated like this:

GeometricSolveValues[s2, {
  PlanarAngle[{b, a, o}], PlanarAngle[{o, a, c}]}]
(* {{0.380506, 0.380506}} *)

The angles are measured in radians here. We note that Mathematica has switched from exact to numerical solution. A comparison of the three scenes is given in the Summary below.

Visualization

Before going to the third scene, we can use RandomInstance to obtain a visualization of the previous scene (Scene 2). We notice that Mathematica has included a visualization of the two equal angles.

inst2 = RandomInstance[s2]

By the way, if the point coordinates are required for another calculation, we can obtain them from the instance like this:

coords = inst2[[1,1]];

It should be noted that each time we evaluate RandomInstance, we expect to get a new visualization and a new set of coordinates.

Scene 3

The third scene uses the second distance condition, AO=4, and the angle bisector condition.

s3 = GeometricScene[{a, b, c, d, o}, {hyp, givens[[{2, 3}]]}];
inst3 = RandomInstance[s3];
 
GeometricSolveValues[inst3,
 {EuclideanDistance[o, d],
  EuclideanDistance[a, c]}]

{{1.42021, 7.47877}}

Note that the argument of GeometricSolveValues can be either a geometric scene or an instance of a scene. A summary of the results of all three scenes, with the full angle at A in degrees, can be calculated like this:

results = Table[ GeometricSolveValues[scene, {
     EuclideanDistance[b, o], EuclideanDistance[a, o],
     PlanarAngle[{b, a, c}]/Degree,
     EuclideanDistance[o, d], EuclideanDistance[a, c]}],
   {scene, {s1, s2, inst3}}];

Join[{{"", "Scene 1", "Scene 2", "Scene 3"}}, 
  Join[{{"BO", "AO", "\[Angle]BAC", "OD", "AC"}}, 
     Flatten[results, 1]] // Transpose // N];

Grid[%, Spacings -> {4, 1}] // TeXForm

$\begin{array}{cccc} \text{} & \text{Scene 1} & \text{Scene 2} & \text{Scene 3} \\ \text{BO} & 2. & 2. & 1.89898 \\ \text{AO} & 4. & 3.8996 & 4. \\ \text{$\angle $BAC} & 40.5416 & 43.6028 & 41.5932 \\ \text{OD} & 1.25 & 1.44828 & 1.42021 \\ \text{AC} & 7.59934 & 7.24138 & 7.47877 \\ \end{array}$

These results support the assertion that taken altogether the three givens are incompatible with the other hypotheses. Different solutions are obtained when any two of the three givens are used. It should also be noted that these results are not random values.

Answer 2

Like this?

Clear["Global`*"];
a = {-x, 0}; c = {x, 0}; b = {0, h}; o = {0, h - 2};
Reduce[{EuclideanDistance[a, b] == 5 == EuclideanDistance[b, c], 
  EuclideanDistance[a, o] == 4, EuclideanDistance[b, o] == 2, x > 0, 
  h > 0}, {x, h}, Reals]

x == Sqrt[231]/4 && h == 13/4

You can find two angle BAO and DAO.

Clear["Global`*"];
a = {-x, 0}; c = {x, 0}; b = {0, h}; o = {0, h - 2};
pts = {a, b, o} /. 
  Solve[{EuclideanDistance[a, b] == 5 == EuclideanDistance[b, c], 
    EuclideanDistance[a, o] == 4, EuclideanDistance[b, o] == 2, x > 0,
     h > 0}, {x, h}, Reals]
angleBAO = 
 VectorAngle[pts[[1, 2]] - pts[[1, 1]], pts[[1, 3]] - pts[[1, 1]]]
angleDAO = 
 VectorAngle[{0, 0} - pts[[1, 1]], pts[[1, 3]] - pts[[1, 1]]]