# Generating numerical value for skin friction coefficient

I am trying to generate the numerical values for the skin friction coefficient by using the value of the parameter in the procedure of the attached code. When I run the attached Mathematica sheet code, It runs successfully but does not (generate) or give me numerical values for the skin friction. Please help me how to set my Mathematica sheet code to solve this issue.

a1 = 0.5; b1 = 1; R1 = 4; Sc1 = 1; Sr1 = 0.5; tend = 0.75; H1 = 0.5; R2 = 0.5; Rd1 = 0.5; Pr1 = 3.97; r1 = 1; Df1 = 1; c1 = 2; c2 = 0.5; c3 = 0.2; c4 = 0.2; uin = 0;
sol = NDSolve[{D[u[t, x], t] - R1*D[u[t, x], x] == a1*D[D[u[t, x], x], x] + b1*D[u[t, x], x]^2*D[D[u[t, x], x], x] - H1*(u[t, x] - uin) + c1*(T[t, x] + R2*phi[t, x]),
D[T[t, x], t] - R1*D[T[t, x], x] == (1/Pr1)*(1 + (4/3)*Rd1)*D[D[T[t, x], x], x] + Df1*D[D[phi[t, x], x], x],
D[phi[t, x], t] - R1*D[phi[t, x], x] == (1/Sc1)*D[D[phi[t, x], x], x] + Sr1*D[D[phi[t, x], x], x] - r1*phi[t, x], {u[0, x] == 0, T[0, x] == 0, phi[0, x] == 0},
{{u[t, 1] == uin, u[t, 0] == 1 + c2*Derivative[0, 1][u][t, 0]}, {T[t, 1] == 0, T[t, 0] == 1 + c3*Derivative[0, 1][T][t, 0]},
{phi[t, 1] == 0, phi[t, 0] == 1 + c4*Derivative[0, 1][phi][t, 0]}}}, {u, T, phi}, {t, 0, tend}, {x, 0, 1}];
D1 = Evaluate[a1*Derivative[0, 1][u][t, 0] + b1*Derivative[0, 1][u][t, 0]^3 /. sol]

NDSolve::ibcinc

• If you plot the outputs from NDSolve they are all zero. You have a problem with your formulation.
– Hugh
Commented Jul 13 at 20:59

When we run code, we see at the end message

NDSolve::ibcinc: Warning: boundary and initial conditions are inconsistent.

Due to this NDSolve computes some solutions that are not satisfier to boundary conditions, as for example u=T=phi=0. We can avoid these discrepancies by adding transition zone in a form

a1 = 0.5; b1 = 1; R1 = 4; Sc1 = 1; Sr1 = 0.5 ; tend = 0.75; H1 = 0.5; \
R2 = 0.5; Rd1 = 0.5; Pr1 = 3.97; r1 = 1; Df1 = 1; c1 = 2; c2 = 0.5; \
c3 = 0.2; c4 = 0.2; uin = 0;

sol = NDSolve[{D[u[t, x], t] - R1*(D[u[t, x], x]) ==
a1*(D[D[u[t, x], x], x]) +
b1*(D[u[t, x], x])^2*D[D[u[t, x], x], x] - H1 (u[t, x] - uin) +
c1*(T[t, x] + R2*phi[t, x]),
D[T[t, x], t] - R1*(D[T[t, x], x]) ==
1/Pr1*(1 + 4/3 Rd1)*D[D[T[t, x], x], x] +
Df1*D[D[phi[t, x], x], x],
D[phi[t, x], t] - R1*(D[phi[t, x], x]) ==
1/Sc1*D[D[phi[t, x], x], x] + Sr1*D[D[phi[t, x], x], x] -
r1*phi[t, x], {u[0, x] == 0, T[0, x] == 0,
phi[0, x] == 0}, {{u[t, 1] == uin,
u[t, 0] ==
1 - Exp[-100 t] + c2*Derivative[0, 1][u][t, 0]}, {T[t, 1] == 0,
T[t, 0] ==
1 - Exp[-100 t] + c3*Derivative[0, 1][T][t, 0]}, {phi[t, 1] ==
0, phi[t, 0] ==
1 - Exp[-100 t] + c4*Derivative[0, 1][phi][t, 0]}}}, {u, T,
phi}, {t, 0, tend}, {x, 0, 1}]

Finally, we have nonzero solution. Visualization To compute friction coefficient we should note first, that D1 is a function of time,

Plot[Evaluate[a1*(Derivative[0, 1][u][t, 0]) +
b1*(Derivative[0, 1][u][t, 0]^3) /. sol[[1]]], {t, 0, tend},
PlotRange -> All, Frame -> True, FrameLabel -> {"t", "D1"}]

We also can compute D1 at t=tend as

D1 =
Evaluate[
a1*(Derivative[0, 1][u][t, 0]) +
b1*(Derivative[0, 1][u][t, 0]^3) /. sol[[1]]] /. t -> tend

Out[]= -2.25662
• Thank you so much respected Professor. Commented Jul 14 at 8:23
• @Tariqhussain You are welcome! Why not to upvote this answer? :) Commented Jul 14 at 9:12