# Why can't the minimum value of this trigonometric function be calculated?

Minimize[{(2 a (a - c) (a + c))/(a^2 - c^2 Cos[\[Theta]]^2), a > 0,
b > 0, c > 0, a^2 - b^2 == c^2, a > b, a > c,
0 <= \[Theta] < \[Pi]}, \[Theta]]


Why can't this minimum value be calculated, where a, b, and c are constants and the angle is the variable?

This problem still cannot be directly solved in version 14.1.

• I'd start with substituting $a=\sqrt{b^2+c^2}$ which reduces the problem to two positive parameters $(b,c)$. Commented Jul 11 at 13:59
• I understand you want some Mathematica code to find the answer but you should note that the answer for any combination of the parameters with the restrictions you have is $\pi/2$. (And this problem could be simplified to just a single parameter $d$ with $\frac{1}{1-d \cos ^2(\theta )}$ and $0<d<1$.)
– JimB
Commented Jul 11 at 14:08
• @Roman I actually tried that too (tried also elimination of c and b, one at time) but still no answer. Commented Jul 11 at 14:26
• If you put any positive rational numbers for $a$ and $c$ with ($a>c$ and completely ignoring $b$) you get $\pi/2$ for the minimum.
– JimB
Commented Jul 11 at 20:05

I think it's worth reporting to WRI. You ask "why it doesn't work," but that does not really appear to be important. I think your input syntax is wrong, but fixing the syntax does not fix the problem.

Here's the calc I approach, and I don't know why Minimize[] does not do something like this:

cons = And @@ {a > 0, b > 0, c > 0, a^2-b^2 == c^2, a > b, a > c, 0 <= θ < π};
cps = Solve[D[(2a (a - c)(a + c))/(a^2 - c^2 Cos[θ]^2), θ] == 0, θ];
twodtest = D[(2a (a - c)(a + c))/(a^2 - c^2 Cos[θ]^2), θ, θ] /. cps //
Simplify;
Reduce[(cons && #1) && Implies[cons, #2 > 0]] &,
{Flatten[cps /. Rule -> Equal], twodtest}] //
Simplify[#, _C \[Element] Integers && cons] &;
Flatten[Solve[#, θ, {C[1]}] & /@ twodtestresults, 1]

(* {{θ -> π/2}} *)


Update: Second approach

Again, one wonders why Minimize does not handle the original problem:

cons = And @@ {a > 0, b > 0, c > 0, a^2-b^2 == c^2, a > b, a > c, 0 <= θ < π};
Minimize[
{(2a (a - c)(a + c))/(a^2 - c^2  cos^2),
{cons, -1 <= cos <= 1}}, cos] //
Simplify[#, {cons, -1 <= cos <= 1}] &
Solve[Cos[θ] == cos && cons /. Last[%], θ, {a, b, c}]
(*
{(2 b^2)/a, {cos -> 0}}
{{θ -> π/2}}
*)


The reduction to polynomials succeeds.

Minimize[{(2  a  (a - c)  (a + c))/(a^2 - c^2  Cos[\[Theta]]^2),
a > 0, b > 0, c > 0, a^2 - b^2 == c^2, a > b, a > c} /.
Cos[\[Theta]] -> (1 - t^2)/(1 + t^2), t] // ToRadicals


{Piecewise[{{(2*(a^2 - c^2))/a, c > 0 && b > 0 && a == Sqrt[b^2 + c^2]}}, Infinity], {t -> Piecewise[{{-1, c > 0 && b > 0 && a == Sqrt[b^2 + c^2]}}, Indeterminate]}}

The rest is left on your own.

Addition. Sorry, the condition  0 <= \[Theta] < \[Pi] where Tan[\[Theta]/2]>=0 should be taken into account.

Minimize[ Union[{(2   a   (a - c)   (a + c))/(a^2 - c^2   Cos[\[Theta]]^2),
a > 0 && b > 0 && c > 0 && a^2 - b^2 == c^2 && a > b && a > c} /.
Cos[\[Theta]] -> (1 - t^2)/(1 + t^2), {t >= 0}], t] // ToRadicals


{Piecewise[{{(2*(a^2 - c^2))/a, c > 0 && b > 0 && a == Sqrt[b^2 + c^2]}}, Infinity], {t -> Piecewise[ {{1, c > 0 && b > 0 && a == Sqrt[b^2 + c^2]}}, Indeterminate]}}