# How can we verify the accuracy of options B, C, and D in this multiple-choice question using alternative methods?

Question：

Set the function $$f(x)=(x-1)^2(x-4)$$, then

A. $$x=3$$ is the inflection point of $$f(x)$$           B. When $$0, $$f(x)

C. When $$1, $$-4            D. When $$-1, $$f(2-x)>f(x)$$

For option B, my approach is:

Clear["*"]
f[x_] := (x - 1)^2 (x - 4)
Reduce[f[x] < f[x^2], x]


For C:

Clear["*"]
f[x_] := (x - 1)^2 (x - 4)
Reduce[-4 < f[2 x - 1] < 0, x]


For D:

Clear["*"]
f[x_] := (x - 1)^2 (x - 4)
Reduce[f[2 - x] > f[x], x]


My method for determining the correctness of the above three options is to solve the inequality and check if the results align with the conditions stated in the options. Is there a direct method to assess the correctness of these three options?

\$Version

(* "14.0.0 for Mac OS X ARM (64-bit) (December 13, 2023)" *)

Clear["Global*"]

f[x_] := (x - 1)^2 (x - 4)

f'[3] == 0

(* True *)


However, it is not unique

sol = Solve[f'[x] == 0, x]

(* {{x -> 1}, {x -> 3}} *)

Plot[f[x], {x, 0, 4},
Epilog -> {Red, AbsolutePointSize[5],
Point[{x, f[x]} /. sol]}]


Assuming[0 < x < 1, f[x] < f[x^2] // Simplify]

(* False *)

Plot[{Callout[f[x], Inactive[f][x], {Scaled[0.5], Above}],
Callout[f[x^2], Inactive[f][x^2], {Scaled[0.5], Below}]}, {x, 0, 1}]


Assuming[1 < x < 2, -4 < f[2 x - 1] < 0 // Simplify]

(* True *)

Plot[f[2 x - 1], {x, 1, 2},
Frame -> True,
GridLines -> {None, {-4, 0}},
GridLinesStyle -> Red]


Assuming[-1 < x < 10, TrueQ[f[2 - x] > f[x]] // Simplify]

(* False *)

NumberLinePlot[{-1 < x < 10, f[2 - x] > f[x]}, x]