1
$\begingroup$

Is it possible to revolve a function around a line instead of an axis?

For instance I would like to revolve the quadratic function:

f[x_]:=-0.45(x-1.5)^2 

Around the x=3, z=0 line.

$\endgroup$
  • 2
    $\begingroup$ Strongly related? $\endgroup$ – Öskå Aug 14 '13 at 8:06
  • $\begingroup$ What do you want to revolve? I may be able to translate all by {-3, 0, 0} and then use RevolutionAxis-> $\endgroup$ – Kuba Aug 14 '13 at 8:07
  • $\begingroup$ I want to revolve a quadratic function: -0.45(x - 1.5)^2 $\endgroup$ – Michael H Aug 14 '13 at 8:19
  • $\begingroup$ Yes, sorry x=3 z=0 $\endgroup$ – Michael H Aug 14 '13 at 8:23
3
$\begingroup$

General approach is covered by this answer form the Q&A which link is provided by Öskå.

As I've said in comments, you may translate your function so the x = 3, z = 0 line will be an y-axis.

f[x_] := (-0.45 (x - 1.5)^2)

Plot[{f[x], f[x + 3]}, {x, -5, 5}, 
     Epilog -> {Thick, Blue, Line[{{3, -25}, {3, 5}}], Red, Line[{{0, -25}, {0, 5}}]}, 
     AxesLabel -> {"x", "y"}, AxesStyle -> Arrowheads@.05]

enter image description here

Then revolve it around y-axis:

plot = RevolutionPlot3D[{x, f[x + 3], 0}, {x, -5, 5},
                      RevolutionAxis -> {0, 1, 0}, AxesOrigin -> {0, 0, 0}, 
                      ImageSize -> 500, PlotRange -> 15, BaseStyle -> Orange,
                      AxesStyle -> {Red, Green, Blue}
                     ]

enter image description here

and translate it back:

Translate[#, {3, 0, 0}] & @@ plot //Graphics3D[#, Axes -> True, PlotRange -> 15,
                                           AxesOrigin -> {0, 0, 0},  ImageSize -> 500,
                                           AxesStyle -> {Red, Green, Blue}] &

enter image description here

| improve this answer | |
$\endgroup$
  • 1
    $\begingroup$ Add a cool MeshShading and you got a Smurf house $\endgroup$ – Öskå Aug 14 '13 at 9:07
  • $\begingroup$ @MichaelH General approach is covered by this answer form this Q&A which link is provided by Oska $\endgroup$ – Kuba Aug 14 '13 at 9:28

Not the answer you're looking for? Browse other questions tagged or ask your own question.