3
$\begingroup$

I am banging my head trying to simplify following expression to get rid of the nonessential "I" (I know, I can do it by hand, but this is only a toy example):

I (Sqrt[-1 + a^2] - Sqrt[-1 + a^2 x^2])

To get:

-Sqrt[1 - a^2] + Sqrt[1 - a^2 x^2]

Not even the following works:

Simplify[I  (Sqrt[-1 + a^2] - Sqrt[-1 + a^2 x^2]) , Assumptions -> {1 < a, 1 < x}]

Correction :

Simplify[I  (Sqrt[-1 + a^2] - Sqrt[-1 + a^2 x^2]) , Assumptions -> {1 > a, 1 > x}]
$\endgroup$
6
  • $\begingroup$ Updated the question. $\endgroup$ Commented Jun 16 at 18:57
  • 1
    $\begingroup$ The I is not nonessential. The two expression are not equivalent. $\endgroup$ Commented Jun 16 at 20:48
  • $\begingroup$ @azerbajdzan Simplify[I (Sqrt[-1 + a^2] - Sqrt[-1 + a^2 x^2]) == Sqrt[1 - a^2] - Sqrt[1 - a^2 x^2], Assumptions -> {1 < a, 1 < x}] returns True $\endgroup$
    – Chris K
    Commented Jun 17 at 3:23
  • 1
    $\begingroup$ @ChrisK It is not the goal of OP to simplify that expression. He's goal is to simplify the expression without Assumptions -> {1 < a, 1 < x}, and this is not equivalent in this case. It is evident from PO's sentence "Not even the following works:". $\endgroup$ Commented Jun 17 at 9:15
  • 1
    $\begingroup$ @ChrisK Notice also that OP changed his second expression just an hour ago (swapping + and -) without any explanation. This affects under which circumstances the identity holds, but in general for all x and a it never holds. $\endgroup$ Commented Jun 17 at 9:26

4 Answers 4

3
$\begingroup$

Use ComplexExpand.

Assuming[0 < a < 1 && 0 < x < 1, 
 I  (Sqrt[-1 + a^2] - Sqrt[-1 + a^2  x^2]) // ComplexExpand // 
  Simplify]

(*-Sqrt[1 - a^2] + Sqrt[1 - a^2 x^2]*)
$\endgroup$
2
$\begingroup$

How about a brute force method for now until better method is found :)

e = I  (Sqrt[-1 + a^2] - Sqrt[-1 + a^2  x^2])
Expand[e] /. Complex[0, b_]*Sqrt[any_] :> Sqrt[any*Complex[0, b]^2]

enter image description here

$\endgroup$
1
$\begingroup$

Another possibility

expr = I (Sqrt[-1 + a^2] - Sqrt[-1 + a^2 x^2]);
(Simplify[# /. {Complex[0, 1] -> Sqrt[-c], 
                Complex[0, -1] -> -Sqrt[-c]}, 
          Assumptions -> {1 < a, 1 < x, c == 1}]) & /@ Expand[expr]
$\endgroup$
0
$\begingroup$

By playing around I found that although

Simplify[I   (Sqrt[-1 + a^2] - Sqrt[-1 + a^2  x^2]), Assumptions -> {a < 1, x < 1}]

does not work, it works if we constrict (although superfluous) the variables more:

Simplify[I   (Sqrt[-1 + a^2] - Sqrt[-1 + a^2  x^2]), Assumptions -> {0 < a < 1, 0 < x < 1}]

-Sqrt[1 - a^2] + Sqrt[1 - a^2 x^2]
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.