How to animate an impossible image

Question

Could someone help me generate movement for this image

This image is like an impossible figure, yet I have seen similar ones but I can't imagine how to give it movement.

thanks in advance

Answer 1

Edit

• To get the original picture orientation,we can add π to θ.

f[s_, θ_] := 
  With[{R = 8, r = 4}, 
   R*{Cos[s], Sin[s], 0} + 
    r*{Cos[θ + π], Sin[θ + π], 
      Sin[θ - s]}];
δθ = 2 π/6;
δs = 2 π/16;
colors = {Yellow, LightYellow, Yellow, Gray, Brown, Gray, Yellow};
Manipulate[
 Graphics3D[
  Thread[{colors, 
    Table[Polygon[{f[s, θ], f[s, θ + δθ], 
       f[s + δs, θ + δθ], 
       f[s + δs, θ]}], {θ, 0 + t, 
      2 π + t, δθ}, {s, 0, 2 π, δs}]}], 
  ViewProjection -> "Orthographic", ViewPoint -> Bottom, 
  Boxed -> False, Lighting -> {{"Ambient", White}}], {t, 0, 2 π}]

Original

As I have mention in the comment, @LukasLang have provided an answer. Here we provide a simplified version.

Clear["Global`*"];
f[s_, θ_] = 
  With[{R = 8, r = 4}, 
   R*{Cos[s], Sin[s], 0} + 
    r*{Cos[θ], Sin[θ], Sin[θ - s]}];
δθ = 2   π/6;
δs = 2   π/16;
colors = ColorData[97] /@ Range[7];
Manipulate[
 Graphics3D[
  Thread[{colors, 
    Table[Polygon[{f[s, θ], f[s, θ + δθ], 
       f[s + δs, θ + δθ], 
       f[s + δs, θ]}], {θ, 0 + t, 
      2   π + t, δθ}, {s, 0, 
      2   π, δs}]}], ViewProjection -> "Orthographic", 
  ViewPoint -> Top, Boxed -> False, 
  Lighting -> {{"Ambient", White}}], {t, 0, 2  π}]