3
$\begingroup$

I am trying to solve this solution

Sin[2 x + Pi/12] == Cos[3 x - Pi/5], -2 Pi <= x <= Pi

I tried

FullSimplify@
 DeleteDuplicates[
  x /. Solve[{Sin[2 x + Pi/12] == Cos[3 x - Pi/5], -2 Pi <= x <= Pi}, {x}]]

I got

enter image description here

I work around

Clear["Global`*"]
a = 2 x + Pi/12;
b = Pi/2 - (3 x - Pi/5);
f[k_] = SolveValues[{a == b + k  2  Pi , -2 Pi <= x <= Pi}, x, Reals]

enter image description here

list1 = k /. Solve[-(637/120) < k < 263/120, k, Integers]

Table[f[k], {k, list1}]

enter image description here

g[k_] = SolveValues[{a == Pi - b + k  2  Pi , -2 Pi <= x <= Pi}, x, Reals]

enter image description here

list1 = k /. Solve[-(73/120) < k < 107/120, k, Integers]
Table[g[k], {k, list1}]

enter image description here

Form two cases, I get eight solutions.

How can I get all exactly solutions without working around?

$\endgroup$
2
  • 1
    $\begingroup$ Solve[Sin[2 x+Pi/12]==Cos[3 x-Pi/5]&&-2 Pi<=x<=Pi//TrigToExp,x] $\endgroup$
    – vector
    Commented May 30 at 7:19
  • $\begingroup$ @vector: This is an answer, not a comment. $\endgroup$
    – user64494
    Commented May 30 at 8:04

2 Answers 2

4
$\begingroup$

TrigFactor helps:

 Solve[TrigFactor[Sin[2  x + Pi/12] - Cos[3  x - Pi/5]] == 0 && 
  x >= -2*Pi && x <= Pi, x, Reals]

{{x -> -((563 \[Pi])/300)}, {x -> -((443 \[Pi])/300)}, {x -> -(( 323 \[Pi])/300)}, {x -> -((203 \[Pi])/300)}, {x -> -((83 \[Pi])/ 300)}, {x -> -((13 \[Pi])/60)}, {x -> (37 \[Pi])/300}, {x -> ( 157 \[Pi])/300}, {x -> (277 \[Pi])/300}}

$\endgroup$
3
$\begingroup$

Given that we know these roots are rational multiples of $\pi$, we can convert the result of Root objects to normal expressions as

Solve[{Sin[2  x + Pi/12] == Cos[3  x - Pi/5], -2  Pi <= x <= 
    Pi}, {x}] /. a_ArcTan :> Pi  Rationalize[N@a/Pi]
 
(*{{x -> -((203 \[Pi])/300)}, {x -> -((83 \[Pi])/300)}, {x -> -((
    13 \[Pi])/60)}, {x -> (37 \[Pi])/
   300}, {x -> -((563 \[Pi])/300)}, {x -> (157 \[Pi])/
   300}, {x -> -((443 \[Pi])/300)}, {x -> (277 \[Pi])/
   300}, {x -> -((323 \[Pi])/300)}}*)
```
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.