7
$\begingroup$

I am having trouble evaluating the following integral, which they say has a solution! Thanks.

Integrate[x^s Exp[-λ x] Sin[y x] LaguerreL[n, s, λ x], {x, 0, ∞},
  Assumptions -> {s > -1, λ > 0, y > 0}];
$\endgroup$
4
  • 1
    $\begingroup$ It evaluates for some values With[{s = 1, λ = 1, n = 3}, Integrate[x^s Exp[-λ x] Sin[y x] LaguerreL[n, s, λ x], {x, 0, ∞}, Assumptions -> y > 0]] giving $\frac{4 \left(5 y^7-10 y^5+y^3\right)}{\left(y^2+1\right)^5}$ $\endgroup$
    – yarchik
    Commented May 25 at 12:04
  • 1
    $\begingroup$ Welcome to Mathematica StackExchange! First, you have an issue in your code: In the integrand, you have λ, but in the assumptions, you have Lambda. These are two different symbols. Also, you have v among assumptions, but there is no v in the integrand. Lastly, can you please specify who is they, and what do they say that the result is? :) $\endgroup$
    – Domen
    Commented May 25 at 12:20
  • 1
    $\begingroup$ You can evaluate the integral for every positive integer $n$, e.g. Column@Table[ Integrate[ x^s Exp[-λ x] Sin[y x] LaguerreL[n, s, λ x], {x, 0, ∞}, Assumptions -> {s > -1, λ > 0, y > 0}], {n, 7}] $\endgroup$
    – Artes
    Commented May 25 at 14:21
  • $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$
    – Michael E2
    Commented May 26 at 18:16

3 Answers 3

9
$\begingroup$

Using: $$L_n^s(\lambda x)=\sum _{k=0}^n \frac{(x \lambda )^k \Gamma (1+n+s) (-n)_k}{k! n! \Gamma (1+k+s)}$$

we have:

F = Simplify[Sum[Integrate[x^s Exp[-λ x] Sin[y x]*((x λ)^
   k Gamma[1 + n + s] Pochhammer[-n, k])/(
  k! n! Gamma[1 + k + s]), {x, 0, ∞}, 
 Assumptions -> {s > -1, λ > 0, y > 0, k >= 0, 
   n ∈ PositiveIntegers}] // FunctionExpand, {k, 0, n}], 
Assumptions -> {s > -1, λ > 0, y > 0, n > 0}]

(*(1/(4 π Gamma[2 + n]))E^(
1/2 (-2 I n π - (3 + n + 2 s) Log[
  1 - (I y)/λ] + (3 + n + 2 s) Log[
  1 + (I y)/λ])) (-1 + E^(
 2 I n π)) (y^2 + λ^2)^(1/2 (-3 - n - s))
 Gamma[1 + n + 
 s] ((y^2 + λ^2)^(
1 + n/2) (E^(
   1/2 (2 + n + s) (Log[1 - (I y)/λ] - 
      Log[1 + (I y)/λ])) (1 - (
     Sqrt[1 + 
       y^2/λ^2] λ^2)/((-I y + λ) Sqrt[
      y^2 + λ^2]))^n - 
  E^(1/2 (4 + n + 3 s) (Log[1 - (I y)/λ] - 
      Log[1 + (I y)/λ])) (1 - (
     Sqrt[1 + 
       y^2/λ^2] λ^2)/((I y + λ) Sqrt[
      y^2 + λ^2]))^n) Gamma[-n] Gamma[2 + n] + λ^(
1 + n) Sqrt[
y^2 + λ^2] (E^(
   1/2 (5 + 2 n + 3 s) (Log[1 - (I y)/λ] - 
      Log[1 + (I y)/λ]))
    Hypergeometric2F1[1, 1, 2 + n, (
    Sqrt[1 - (I y)/λ] λ)/(
    Sqrt[1 + (I y)/λ] Sqrt[y^2 + λ^2])] - 
  E^(1/2 (1 + s) (Log[1 - (I y)/λ] - 
      Log[1 + (I y)/λ]))
    Hypergeometric2F1[1, 1, 2 + n, (
    Sqrt[1 + (I y)/λ] λ)/(
    Sqrt[1 - (I y)/λ] Sqrt[y^2 + λ^2])]))*)

 With[{s = 2, λ = 1, y = 2, n = 5}, Integrate[x^s Exp[-λ x] Sin[y x] LaguerreL[n, s, λ x], {x, 0, ∞}]]
 (*708288/390625*)
 Limit[With[{s = 2, λ = 1, y = 2}, Evaluate@F], n -> 5] // Quiet // FullSimplify(*OK*)
 (*708288/390625*)
$\endgroup$
4
$\begingroup$

This integral is given as Eq. 7.417 in Table of integrals, series, and products by Gradshteyn and Ryzhik (7th ed.).

I do not know how to derive this answer with MA, but it is possible to find a simple recursive relation. For convenience and without loosing generality define $$ f(n, s, y)= \int_0^\infty x^s e^{-x} L_n(x) \sin \left(\frac{x}{y}\right)dx. $$ For $s=0$, the integral can be performed with MA:

Integrate[ Exp[-x] Sin[x/y] LaguerreL[n, x], {x, 0, ∞}, 
           Assumptions -> {y > 0, n > -1, Element[n, Integers]}]

(* y (1+y^2)^(-(1/2)-n/2) Cos[(1+n) ArcTan[y]]*)

This can be written in terms of the Chebyshev polynomials $$ f(n, 0, y)= \frac{y T_{n+1}\left(\frac{1}{\sqrt{y^2+1}}\right)}{\sqrt{y^2+1}^{n+1}}. $$

Now we can use a recursion:

$$xL_n^{s+1}(x)=(n+s)L_{n-1}^{s+1}(x)+(n-x)L_n^{s}(x)$$

to get the recursive formula

F[n_, 0, y_] := y/(Sqrt[1 + y^2])^(n + 1)  ChebyshevT[1 + n, 1/Sqrt[1 + y^2]]
F[n_, a_, y_] := (n + a) F[n, a - 1, y] - (n + 1) F[n + 1, a - 1, y]

Now we can do some verification

F[2, 2, y] // Simplify
Integrate[x^2 Exp[-x] Sin[x/y] LaguerreL[2, 2, x], {x, 0, ∞}, Assumptions -> {s > -1, y > 0}]

(* Both give: -((12 y^3 (1-10 y^2+5 y^4))/(1+y^2)^5) *)
$\endgroup$
1
$\begingroup$

The integral under consideration can be treated as

MellinTransform[ x* Exp[-\[Lambda]  x]*Sin[y  x]*  
LaguerreL[n, s, \[Lambda]  x], x, s, Assumptions -> {\[Lambda] > 0, y > 0}]//FunctionExpand

ConditionalExpression[-1/( y Sqrt[(y^2 + \[Lambda]^2)/\[Lambda]^2] Gamma[1 + n]) (1 + y^2/\[Lambda]^2)^(-(n/2) - s/ 2) (y^2/\[Lambda]^2)^(n/2) \[Lambda]^(-1 - s) Gamma[1 + n + s] (y Cos[ 2 (1/2 + n/2 + s/2) ArcTan[ y/\[Lambda]]] Csc[(-(n/2) + (1 + n)/2) \[Pi]] Sin[(n \[Pi])/ 2] + Sqrt[ y^2/\[Lambda]^2] \[Lambda] Cos[(n \[Pi])/ 2] Csc[(1/2 (-1 - n) + n/2) \[Pi]] Sin[ ArcTan[y/\[Lambda]] + n ArcTan[y/\[Lambda]] + s ArcTan[y/\[Lambda]]]), {True, True}]

I don't understand much the condition {True, True}.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.