# How to draw circle passing through points in 3D?

Let SABC be a pyramid, the triangle ABC be a right triangle at B; The line SA perpendicular to the plane ABC; E is projection point of A on the line SB; F is projection point of A on the line SC. How can I draw circle passing through points B, C, E? I tried

Clear["Global*"];
a = 3;
b = 4;
h = 5;
pA = {0, 0, 0};
pC = {Sqrt[a^2 + b^2], 0, 0};
pB = {b^2/Sqrt[a^2 + b^2], -Sqrt[a^2 b^2]/Sqrt[a^2 + b^2], 0};
pS = {0, 0, h};
lSB = InfiniteLine[{pS, pB}];
lSC = InfiniteLine[{pS, pC}];
pE = RegionNearest[lSB, pA];
d1 = RegionDistance[lSB, pA];
pF = RegionNearest[lSC, pA] // Simplify;
d2 = RegionDistance[lSC, pA] // Simplify;
\[ScriptCapitalR] = ConvexHullRegion[{pA, pB, pC, pS}];
Graphics3D[{EdgeForm[{Thick, Blue}],
FaceForm[{Pink, Opacity[0.2]}], \[ScriptCapitalR],
Text[Style["A", Italic, 14, FontFamily -> "Times"], {0, 0, -0.3}],
Text[Style["B", Italic, 14, FontFamily -> "Times"], {b^2/Sqrt[
a^2 + b^2], -Sqrt[a^2 b^2]/Sqrt[a^2 + b^2], -.3}],
Text[Style["C", Italic, 14, FontFamily -> "Times"], {Sqrt[
a^2 + b^2], 0.3, 0}],
Text[Style["S", Italic, 14, FontFamily -> "Times"], {0, 0,
h + .3}],
Text[Style["F", Italic, 14, FontFamily -> "Times"], {5/2, 0,
5/2 + .3}],
Text[Style["E", Italic, 14, FontFamily -> "Times"], {80/
41, -(60/41) + .3, 80/41}], , Thick, Orange,
Line[{{pE, pA}, {pF, pA}, {pF, pE}}]
}, Boxed -> False]


I got

How can I get like this?

reg=Region[Style[
RegionIntersection[Circumsphere[{pB, pC, pF, pE}],
InfinitePlane[pB, {pB - pC, pF - pB}]], Directive@{Cyan, Thick}]]


• We can also find the center and radius of such circle.
Solve[{{x, y, z} ∈ Polygon[{pB, pC, pF, pE}],
EuclideanDistance[{x, y, z}, #] & /@ {pB, pC, pF, pE} == r}]


{{r -> 25/(2 Sqrt[41]), x -> 285/82, y -> -(30/41), z -> 40/41}}.

• You can do InfinitePlane[{pB, pC, pE}]. Commented May 3 at 11:52
• @cvgmt When I run your code, I get only a circle. Where I put your code? Commented May 3 at 12:01
• Show[reg,......] Commented May 3 at 12:06
• @cvgmt Thank you very much. Commented May 3 at 15:27
• @cvgmt I have label of two points E and F` by hand. How can I put labels automatically? Commented May 4 at 0:05