2
$\begingroup$

Let $z$ and $w$ be two complex numbers satisfying conditions: $|z| = 2$ and $|w i - 2 + 5i| = 1.$ How can I find the minimum of $|z^2 - w z - 4|$?

I tried with setting $z = a + b i$ and $w = x + y i$:

Minimize[
 ComplexExpand /@ {Abs[(a + b  I)^2 - (x + I  y) (a + b  I) - 4 ], 
   Abs[a + b  I] == 2 && Abs[I  (x + I  y) - 2 + 5 I] == 1}, {x, y, 
  a, b}]

However, I can not get the result.

$\endgroup$

2 Answers 2

5
$\begingroup$
  • $|z|=2$ means $z=2e^{i\alpha}$
  • $|i w-2+5i|=1$ means $i w-2+5i=e^{i\beta}$

From these,

z = 2 E^(I*ɑ);
w = (E^(I*β) + 2 - 5 I)/I;

Abs[z^2 - w z - 4]^2 // ComplexExpand // FullSimplify
(*    -8 (-19 + 4 Cos[2ɑ] - 2 Cos[β] - 4 (2 + Cos[β]) Sin[ɑ] + 5 Sin[β])    *)

Minimize[%, {ɑ, β}, Reals]
(*    {64, {ɑ -> -293π/6, β -> -19π/2}}    *)

Concretely,

{z, w} /. {ɑ -> -293π/6, β -> -19π/2} // ComplexExpand
(*    {-I - Sqrt[3], -4 - 2 I}    *)

Geometric validation: there are two minima $z=-i\pm\sqrt{3}$ and $w=-4-2i$,

DensityPlot[Sqrt[-8 (-19 + 4 Cos[2ɑ] - 2 Cos[β] - 4 (2 + Cos[β]) Sin[ɑ] + 5 Sin[β])],
        {ɑ, 0, 2π}, {β, 0, 2π},
        MeshFunctions -> {#3 &}, Mesh -> {{8.01}}, MeshStyle -> White,
        PlotPoints -> 100]

enter image description here

$\endgroup$
1
  • $\begingroup$ Reals in Minimize[%, {ɑ, β}, Reals] is superfluous. $\endgroup$
    – user64494
    Commented Apr 26 at 7:33
4
$\begingroup$

Let us put z=2*Exp[I*t] and I*w - 2 +5*I = Exp[I*s]. The the task can be written as

Minimize[{ComplexExpand[Abs[(2*Exp[I*t])^2 - (Exp[I*s] + 2 - 5*I)/I *2*
Exp[I*t] - 4]^2], t > -Pi && t <= Pi && s > -Pi && s <= Pi}, {s, t}]

{64, {s -> \[Pi]/2, t -> -((5 \[Pi])/6)}}

$\endgroup$
0

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.