5
$\begingroup$

Working the problem of $$I_n=\int_0^1 \frac{\tan ^{-1}\left(x^n\right)}{\sqrt{1-x^n}} \, dx$$ which I have not be able to compute with Mathematica. A tedious work gave the result $$I_n=\frac{\sqrt{\pi }}{n}\,\,\frac{\Gamma \left(\frac{n+1}{n}\right)}{\Gamma \left(\frac{3 n+2}{2 n}\right)}\,\,\,\, _4F_3\left(\frac{1}{2},1,\frac{n+1}{2 n},\frac{2 n+1}{2 n};\frac{3}{2},\frac{3 n+2}{4 n},\frac{5 n+2}{4 n};-1\right)$$ which works for any $n$ (even complex).

The syntax is

  (Sqrt[Pi]*Gamma[(1 + n)/n]*HypergeometricPFQ[{1/2, 1, 1/2 + 1/(2*n), 
   1 + 1/(2*n)}, {3/2, 3/4 + 1/(2*n), 5/4 + 1/(2*n)}, -1])/  (n*Gamma[(2 + 3*n)/(2*n)])

Since Mathematica was not able to compute the integral AsymptoticIntegrate is of no help.

Empirically, it seems that $n^2 I_n$ is very close to linearity.

Is there any hope to obtain the asymptotics ?

Thanks in advance.

$\endgroup$
4
  • $\begingroup$ Is there a reason why Asymptotic[yourfunction] is not an option? $\endgroup$
    – mattiav27
    Apr 17 at 7:48
  • $\begingroup$ Both Integrate[ArcTan[x^n]/Sqrt[1 - x^n], {x, 0, 1}, Assumptions -> n > 0] and Integrate[ArcTan[x^n]/Sqrt[1 - x^n], {x, 0, 1}, Assumptions ->n\[Element] PositiveIntegers] return the input in 14.0 on Windows 10. $\endgroup$
    – user64494
    Apr 17 at 7:57
  • $\begingroup$ @user64494. This is what I had with version 13.0. It took me days of work to arrive at the result. $\endgroup$ Apr 17 at 8:07
  • $\begingroup$ @mattiav27; Have a look at the comment just below your. Cheers $\endgroup$ Apr 17 at 8:08

4 Answers 4

4
$\begingroup$

The following proves your expectations.

FullSimplify[Series[Sqrt[Pi]*Gamma[(1 + n)/n]*
HypergeometricPFQ[{1/2, 1, 1/2 + 1/(2*n), 1 + 1/(2*n)},
{3/2,3/4 + 1/(2*n), 5/4 + 1/(2*n)}, -1]/(n*
Gamma[(2 + 3*n)/(2*n)]), {n, Infinity, 2}] // Normal]

$$\frac{\text{HypergeometricPFQ}^{(\{0,0,0,0\},\{0,0,1\},0)}\left(\left\{\frac{1}{2},1,\frac{1}{2},1\right\},\left\{\frac{3}{2},\frac{3}{4},\frac{5}{4}\right\},-1\right)+\text{HypergeometricPFQ}^{(\{0,0,0,0\},\{0,1,0\},0)}\left(\left\{\frac{1}{2},1,\frac{1}{2},1\right\},\left\{\frac{3}{2},\frac{3}{4},\frac{5}{4}\right\},-1\right)+\text{HypergeometricPFQ}^{(\{0,0,0,1\},\{0,0,0\},0)}\left(\left\{\frac{1}{2},1,\frac{1}{2},1\right\},\left\{\frac{3}{2},\frac{3}{4},\frac{5}{4}\right\},-1\right)+\text{HypergeometricPFQ}^{(\{0,0,1,0\},\{0,0,0\},0)}\left(\left\{\frac{1}{2},1,\frac{1}{2},1\right\},\left\{\frac{3}{2},\frac{3}{4},\frac{5}{4}\right\},-1\right)+2 (n-2+\log (4)) \, _4F_3\left(\frac{1}{2},\frac{1}{2},1,1;\frac{3}{4},\frac{5}{4},\frac{3}{2};-1\right)}{n^2} $$

Expand[N[%]]

$$\frac{1.74825}{n}-\frac{1.17554}{n^2} $$

$\endgroup$
3
  • 1
    $\begingroup$ The same is produced by Asymptotic[ Sqrt[Pi]*Gamma[(1 + n)/n]* HypergeometricPFQ[{1/2, 1, 1/2 + 1/(2*n), 1 + 1/(2*n)}, {3/2, 3/4 + 1/(2*n), 5/4 + 1/(2*n)}, -1]/(n* Gamma[(2 + 3*n)/(2*n)]), {n, Infinity, 2}] // N. $\endgroup$
    – user64494
    Apr 17 at 8:17
  • $\begingroup$ The last one is very good. (+1). Do you knoaw what is the value of HypergeometricPFQ[{1/2, 1/2, 1, 1}, {3/4, 5/4, 3/2}, -1] ? $\endgroup$ Apr 17 at 8:34
  • $\begingroup$ Thanks to the isc, the front factor is $$\sim \frac 1 {10}\,\frac{\Gamma \left(\frac{1}{8}\right) \,\,\Gamma \left(\frac{13}{20}\right)}{\Gamma \left(\frac{31}{40}\right)}$$ (absolute error $2.6\times 10^{-8}$ $\endgroup$ Apr 17 at 9:05
4
$\begingroup$

Another way to get @user64494 result:

Normal@Series[ArcTan[x^n]/Sqrt[1 - x^n], {n, Infinity, 2}]
(*(I Log[1 - I x^n])/(2 Sqrt[1 - x^n]) - (I Log[1 + I x^n])/( 2 Sqrt[1 - x^n])*)

Simplify[Integrate[(I Log[1 - I x^n])/(2 Sqrt[1 - x^n]), {x, 0, 1}, GenerateConditions -> False] + Integrate[-((I Log[1 + I x^n])/(2 Sqrt[1 - x^n])), {x, 0, 1}, GenerateConditions -> False]];
Asymptotic[%, {n, Infinity, 2}] // N // Chop

(*-(1.17554/n^2) + 1.74825/n*)
$\endgroup$
1
  • $\begingroup$ With the two integrals you get an expression involving HypergeometricPFQRegularized and Gamma functions $\endgroup$
    – mattiav27
    Apr 17 at 14:57
1
$\begingroup$

With AsymptoticIntegrate works fine:

$Version
(*"13.3.0 for Microsoft Windows (64-bit) (June 3, 2023)"*)
 
AsymptoticIntegrate[ArcTan[x^n]/Sqrt[1 - x^n] // TrigToExp, {x, 0, 1}, {n, Infinity, 2}]

 (*((-I)*(ArcSin[(-1)^(1/4)]^2 + ArcSinh[(-1)^(1/4)]^2))/n + 
 (Sqrt[Pi]*(((2*I)*EulerGamma*(ArcSin[(-1)^(1/4)]^2 + 
 ArcSinh[(-1)^(1/4)]^2))/Sqrt[Pi] + 
 Derivative[{0, 0, 0}, {0, 1}, 0][HypergeometricPFQRegularized][{1, 1, 1}, {2, 3/2}, -I] + 
 Derivative[{0, 0, 0}, {0, 1}, 0][HypergeometricPFQRegularized][{1, 1, 1}, {2, 3/2}, I] + 
 Derivative[{0, 0, 1}, {0, 0}, 0][HypergeometricPFQRegularized][{1, 1, 1}, {2, 3/2}, -I] + 
 Derivative[{0, 0, 1}, {0, 0}, 0][HypergeometricPFQRegularized][{1, 1, 1}, {2, 3/2}, I]))/(2*n^2)*)

% // N
(*-((1.17554 + 0. I)/n^2) + (1.74825 + 0. I)/n*)

To compute integral we use a trick: $$\int_0^1 \frac{\tan ^{-1}\left(x^n\right)}{\sqrt{1-x^n}} \, dx$$

Integrate[Integrate[D[ArcTan[a x^n]/Sqrt[1 - x^n], a], {x, 0, 1},  
GenerateConditions -> False], {a, 0, 1}] // FunctionExpand

(* (Sqrt[\[Pi]]Gamma[1/n] HypergeometricPFQ[{1/2, 1, 1/2 + 1/(2 n), 1 + 1/(2 n)}, {3/2, 
 3/4 + 1/(2 n), 5/4 + 1/(2 n)}, -1])/(n^2 Gamma[3/2 + 1/n])*)
$\endgroup$
0
$\begingroup$

The solution has already been posted; here are some semi-explicit forms of the series-expansion coefficients:

Sum[(-1)^q/((q + 1/2) Binomial[2 q + 1/2, 1/2]), {q, 0, ∞}]
(*    2 HypergeometricPFQ[{1/2, 1/2, 1, 1}, {3/4, 5/4, 3/2}, -1]    *)

NSum[-((-1)^q/((q + 1/2) Binomial[2 q + 1/2, 1/2])) *
     (HarmonicNumber[2 q + 1/2] - HarmonicNumber[2 q]), {q, 0, ∞}]
(*    -1.17554    *)
$\endgroup$
3
  • $\begingroup$ Nice formula. Thanks. By the way, concerning your book, I would like to be in touch with you. If you agree, send me an e-mail.. Do you have any idea of the asymptotics of $$,\, _4F_3\left(\frac{1}{2},1,\frac{n+1}{2 n},\frac{2 n+1}{2 n};\frac{3}{2},\frac{3 n+2}{4 n},\frac{5 n+2}{4 n};-1\right)$$ ? $\endgroup$ Apr 18 at 8:40
  • $\begingroup$ I contacted you by Email. As for f[n_] = HypergeometricPFQ[{1/2, 1, (n+1)/(2n), (2n+1)/(2n)}, {3/2, (3n+2)/(4n), (5n+2)/(4n)}, -1] we have Series[f[n], {n, ∞, 2}] // N giving $0.874127-\frac{0.0513137}{n}+\frac{0.0293261}{n^2}+O(n^{-3})$. Are you looking for sum formulations of these coefficients? $\endgroup$
    – Roman
    Apr 18 at 11:37
  • $\begingroup$ Yes, I would like to know what they are. Have a look at math.stackexchange.com/questions/4901127/… for the first coefficient. $\endgroup$ Apr 18 at 11:46

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.