6
$\begingroup$

I have this picture, knowing that $AC=2$. The point $B$ is midpoint of $AC$, $D$ is intersection point of the semicirle and arc center at $B$ and radius 1. I want to rotate the region with gray fill aroun the line $AC$.

I put

coordinate of $D$ is found

SolveValues[{y == Sqrt[1 - x^2], (x + 1)^2 + y^2 == 1}, {x, y}, Reals]

{{-(1/2), Sqrt[3]/2}}

I put

Clear["Global`*"];
b = {0, 0};
a = {-1, 0};
c = {1, 0};
d = {-(1/2), Sqrt[3]/2};
f[x_] := Sqrt[1 - x^2];
g[x_] = Sqrt[1 - (x + 1)^2 ];

enter image description here

$\endgroup$

2 Answers 2

7
$\begingroup$
Clear["Global`*"];
cir1[t_] := {Cos[t], Sin[t]};
cir2[s_] := {-1, 0} + {Cos[s], Sin[s]};
{s0, t0} = {s, t} /. 
  First@FindInstance[{cir2[s] == cir1[t], 0 <= s <= π, 
     0 <= t <= π}, {s, t}]
Show[ParametricPlot[cir1[t], {t, 0, t0}], 
 ParametricPlot[cir2[s], {s, 0, s0}]]

enter image description here

Show[RevolutionPlot3D[cir1[t] // Evaluate, {t, 0, t0}, 
  RevolutionAxis -> {1, 0, 0}], 
 RevolutionPlot3D[cir2[s] // Evaluate, {s, 0, s0}, 
  RevolutionAxis -> {1, 0, 0}], PlotRange -> All, Boxed -> False, 
 Axes -> False]

enter image description here

$\endgroup$
6
$\begingroup$
b1 = Ball[{0, 0, 0}, 1];
b2 = Ball[{-1, 0, 0}, 1];
rd = RegionDifference[b1, b2];

RegionImage@rd

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.