I have tried to solve the Schrödinger equation for the Morse potential using Mathematica. I am using Mathematica 12, and I have written the following code:

op = {-y''[x] + 100*(1 - E^(x))^2*y[x] + DirichletCondition[y[x] == 0, x == -Infinity || x == Infinity]}
DEigensystem[op, y[x], {x, -Infinity, Infinity}, 5]

I want to use the DEigensystem command. I am not getting any results. What is the error?

  • 1
    $\begingroup$ Do you expect that this differential equation has an analytic solution? Also, why are you adding the boundary condition to the differential equation? This syntax is wrong (as far as I know). $\endgroup$
    – march
    Commented Apr 8 at 16:05
  • 1
    $\begingroup$ Do you mean this potential en.wikipedia.org/wiki/Morse_potential ? $\endgroup$ Commented Apr 8 at 16:34
  • $\begingroup$ Υes, that's what I mean, and I want to use DEigensystem to find the first 5 eigenvalues and eigenfunctions. I have found the eigenvalues using the Sturm-Liouville theory, but I don't know how Mathematica will give me the answer using this specific command. $\endgroup$ Commented Apr 8 at 16:43

1 Answer 1


Are you looking for a numerical solution?

λ = 10;
V[x_] = λ^2*(1 - E^x)^2;

eig = NDEigensystem[-y''[x] + V[x] y[x], y[x], {x, -20, 10}, 10,
  Method -> {"PDEDiscretization" -> {"FiniteElement", {"MeshOptions" -> {"MaxCellMeasure" -> 0.01}}}}];

(*    {9.75, 27.75, 43.75, 57.75, 69.75, 79.75, 87.75, 93.75, 97.75, 99.75}    *)

Plot[Evaluate[eig[[2]]], {x, -20, 2}, PlotRange -> All]

enter image description here

These eigenvalues match the analytic expressions:

Table[λ^2 - (λ - n - 1/2)^2, {n, 0, 9}] // N
(*    {9.75, 27.75, 43.75, 57.75, 69.75, 79.75, 87.75, 93.75, 97.75, 99.75}    *)

You can get the general form of the solution from the eigenvalue equation at energy $e_n=\lambda^2-\left(\lambda-n-\frac12\right)^2$:

Clear[λ, V]
V[x_] = λ^2*(1 - E^x)^2;
e[n_] = λ^2 - (λ - n - 1/2)^2;
Assuming[0 <= n < λ - 1/2 && Element[x, Reals],
  DSolveValue[-y''[x] + V[x] y[x] == e[n] y[x], y[x], x] // FullSimplify]
(*    E^(x (1/2+n-λ) - E^x λ) (
        C[1] HypergeometricU[1+n-2λ, 2+2n-2λ, 2 E^x λ] +
        C[2] LaguerreL[-1-n+2λ, 1+2n-2λ, 2E^xλ])            *)

and notice that the Laguerre polynomials are divergent while the hypergeometric functions satisfy the boundary conditions. From this we get the unnormalized eigenfunctions with $C_1=1$ and $C_2=0$:

φ[λ_, n_, x_] = E^(x (1/2+n-λ) - E^x λ) HypergeometricU[1+n-2λ, 2+2n-2λ, 2 E^x λ];

With normalization, obtained by integrating the above for several values of $n$ and using FindSequenceFunction to discover the pattern,

φ[λ_, n_, x_] = ((n! Gamma[2λ-n] (2λ)^(2λ-2n-1))/(2λ-2n-1))^(-1/2) E^(x (1/2+n-λ) - E^x λ) *
  HypergeometricU[1+n-2λ, 2+2n-2λ, 2 E^x λ];

With[{λ = 10},
  Plot[Evaluate@Table[φ[λ, n, x], {n, 0, λ - 1/2}],
       {x, -20, 2}, PlotRange -> All]]

enter image description here

Further, noticing that $U(a,b,z)=-(-1)^{a+b} z^{1-b} (b-a-1)! L_{b-a-1}^{1-b}(z)$, we can rewrite the normalized eigenfunctions in terms of generalized Laguerre polynomials:

φ[λ_, n_, x_] = Sqrt[((2λ E^x)^(2λ-2n-1) E^(-2λ E^x) (2λ-2n-1) n!)/Gamma[2λ-n]] *
  LaguerreL[n, 2λ-2n-1, 2λ E^x];
  • $\begingroup$ Thank you very much, I will make use of the numerical solution :) . Is it not possible to solve it analytically? $\endgroup$ Commented Apr 8 at 22:01
  • $\begingroup$ It is known that oscillator in the Morse potential can be solved almost exactly. In the sense that zero boundary condition occur not at infinity, but at some finite point at which wave function is very close to zero. After replacing in the solution that finite point by infinity we can write exact solution in terms of LaguerreL[ ] function, see S. Flugge, "Practical Quantum Mechanics I", Springer-Verlag, 1971 for details. $\endgroup$
    – Acus
    Commented Apr 9 at 6:11
  • $\begingroup$ Thank you very much for the response, I was simply interested in finding a way to use the 'DEigensystem' command to proceed and solve this problem globally with Mathematica. $\endgroup$ Commented Apr 9 at 10:57
  • 2
    $\begingroup$ I've added some analytic work, please have a look! $\endgroup$
    – Roman
    Commented Apr 9 at 11:57

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.