8
$\begingroup$

Herbert W. Franke

Herbert W. Franke (1927 - 2022) was an Austrian scientist and writer. He was one of the important early computer artists, creating digital art since the early 1950s. Franke, a jack-of-many-trades, was also active in the fields of future research and speleology. And he is considered to be the most sophisticated German writing Science Fiction author. Since 1995 Franke used Mathematica for some of his productions.

enter image description here

Herbert W. Franke producing oscillograms, 1954

Franke studied physics, mathematics and philosophy in Vienna. He received his doctorate in theoretical physics in 1950 by writing a dissertation about electron optics. From 1973 to 1997 he held a lectureship in "Cybernetical Aesthetic" at Munich University (LMU). His works are featured in major international museums. The Herbert W. Franke archive is at the ZKM Center for Art and Media in Karlsruhe.

Pendulum oscillograms

enter image description here

Herbert W. Franke, oscilogram, early 1950's

Since the early 1950's Herbert W. Franke produced pendulum oscillograms in moving a Contaflex mirror reflex camera before the screen of a cathode-ray oscillograph. The oscillograph was connected to a small computer custom-made for his needs and capable to produce elementary curves.

Electronic Einstein

enter image description here

Herbert W. Franke, Elekronischer Einstein, 1972

The "Electronic Einstein" is one of Franke's most famous works, which was featured in many publications. First, a black-and-white photograph of Einstein was scanned and the resulting digital code was stored using punched tape. The image data thus captured was then fed into a Siemens computer, 'Bildspeicher N', a medical diagnostic device producing scintigrams, a type of medical imagery that uses radioactive material to show up tissue or organs in the human body. Photographs were taken directly from the screen, grouped together in a matrix arrangement and reproduced as offset lithographs.

Reproduction attempt

Since I'm a newbie to Mathematica's extensive image processing capabilities, I used the Documentation to arrange image functions through trial and error. Here is what I finally got:

img = Import["mypath" <> "einstein.jpg"]

enter image description here

f = 
  ImageResize[#, {50}] & @ Colorize[#, ColorFunction -> "RedBlueTones"] & @ 
    Rasterize[#, RasterSize -> 100] &;

GraphicsGrid[
 {{f @ Blur[#,  5] & @ img,
   f @ Blur[#,  2] & @ MorphologicalBinarize[img, {0.2, 0.9}]},
  {f @ Blur[#, 20] & @ MorphologicalBinarize[img, {0.4, 0.9}],
   f @ Blur[#, 50] & @ MorphologicalBinarize[img, {0.6, 0.9}]}}]

enter image description here

Question

Unfortunately, my attempt is miles away from the aesthetic charm of the original. Among other things, I miss the uniform black background, the accentuated borders and the arrangement of three main colours. What better alternatives do we have?

Improve this question
$\endgroup$
3
  • 1
    $\begingroup$ Not sure how to go about this yet, but to get rid of the background, you can do $$ $$ img0 = Import@"https://i.sstatic.net/ghokL.jpg"; $$ $$ img = ImageSaliencyFilter[img0]*img0 $$ $$ before applying your function f to img and blurring. I am playing around with the ColorFunction right now in f to see if I can get something more closely resembling Franke's original work. $\endgroup$
    – ydd
    Commented Apr 2 at 13:33
  • $\begingroup$ Thanks, ydd, a nice improvement $\endgroup$
    – eldo
    Commented Apr 2 at 15:00
  • $\begingroup$ Using your ` ImageSaliencyFilter` an acceptable answer could be: ColorFunction -> (Blend[{Black, RGBColor[0, 0.2, 0.5, 0.8], RGBColor[1, 0.5, 0, 0.8]}, #] &)] and the second image with Blur of 10 and MorphologicalBinarize - parameters of {0.5, 0.2}. You could post this as an answer. $\endgroup$
    – eldo
    Commented Apr 3 at 9:05

1 Answer 1

Reset to default
4
$\begingroup$

Trying to reproduce the Elekronischer Einstein using ImageSaliencyFilter suggested by ydd for the background, together with ColorQuantize and GaussianFilter for the metamorphosis.

colorscheme = Map[RGBColor, {
   {{.04, .04, .04}, {.08, .5, .7}, {.8, .8, .7}, {.9, .8, .5}, {.04, .04, .04}, {.08, .5, .7}}
 , {{.04, .04, .04}, {.08, .5, .7}, {.7, .4, .3}, {.7, .4, .3}, {.03, .14, .34}, {.03, .25, .57}}
 , {{.04, .04, .04}, {.54, .69, .80}, {.17, .46, .68}, {.06, .22, .42}, {.84, .45, .12} , {.8, .8, .7}}
 , {{.54, .69, .80}, {.17, .46, .68}, {.51, .69, .69}, {.84, .45, .12}, {.8, .8, .7}, {.17, .46, .68}}
 , {{.08, .5, .7}, {.51, .69, .69}, {.6, .2, .09}, {.84, .45, .12}, {.8, .8, .7}, {.26, .50, 44}}
 }, {2}];

ArrayPlot[colorscheme, ImageSize -> Tiny]

enter image description here

transform[i_, n_] := 
 ColorQuantize[
  ImageMultiply[#, ImageSaliencyFilter@#] &@
   Colorize[GaussianFilter[i, 2^n], 
    ColorFunction -> (Blend[colorscheme[[n]], #] &)], 8, Dithering -> False]

n = 0;
img = Import@"https://i.sstatic.net/ghokL.jpg";
metamorphosis = 
  NestList[(++n; transform[#, n]) &, 
   ImageMultiply[#, ImageSaliencyFilter[#]] &@
    ColorQuantize[
     Colorize[GaussianFilter[img, 6], 
       ColorFunction -> ColorData["DeepSeaColors"]] // 
      Rasterize[#, RasterSize -> 80] &, 7, Dithering -> False], 5];
GraphicsGrid[TakeDrop[metamorphosis, 3], Spacings -> 3, ImageSize -> Large]

enter image description here

Improve this answer
$\endgroup$
1
  • 1
    $\begingroup$ Thank you, vindobona, for this great answer $\endgroup$
    – eldo
    Commented Apr 5 at 6:17

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.