# Interpreting the output of double integral over a Circle

Clear["Global*"];

f[x_, y_] := 9 - x^2 - y^2;

Integrate[f[x, y], {x, -1, 1}, {y, -Sqrt[1 - x^2], Sqrt[1 - x^2]}]

Integrate[f[x, y], {x, y} ∈ Disk[]]


Both give:

(17 π)/2

Visualization:

p1 = Plot3D[f[x, y], {x, -3, 3}, {y, -3, 3}
, PlotStyle -> None
, PlotRange -> {{-3, 3}, {-3, 3}, {0, 10}}
, ClippingStyle -> None
, ImageSize -> 400
];
p2 = Plot3D[f[x, y], {x, y} ∈ Disk[]
, Filling -> Bottom
, FillingStyle -> Opacity[0.5]
, PlotRange -> {0, 9}
];
Show[p1, p2]


Question

What (if any) is a possible interpretation for 16 π that is generated by:

Integrate[f[x, y], {x, y} ∈ Circle[]]


• It is the area of lateral curved surface of the cylinder. Radius of the cylinder is 1 so its circumference is 2π, its height is 8, i.e. the area is 2π*8 = 16 π. Feb 10 at 13:07

Integrate[f[x, y], {x, y} ∈ Circle[]]


16 π

is the line integrate https://en.wikipedia.org/wiki/Line_integral

$$\int_{\mathcal{C}} f(\mathbf{r})\, ds = \int_a^b f\left(\mathbf{r}(t)\right) \left|\mathbf{r}'(t)\right| \, dt$$ the same as

(* \$Version 14.0 *)
f[x_, y_] := 9 - x^2 - y^2;
LineIntegrate[f[x, y], {x, y} ∈ Circle[{0, 0}, 1]]


16 π.

We can also calculus it by the definiton of line integral.

f[x_, y_] := 9 - x^2 - y^2;
x[t_] := Cos[t];
y[t_] := Sin[t];
Integrate[
f[x[t], y[t]]  Sqrt[{x'[t], y'[t]} . {x'[t], y'[t]}], {t, 0,
2  π}]
Integrate[f[x[t], y[t]]  Norm[{x'[t], y'[t]}], {t, 0, 2  π}]


16 π

• So the surface area of the vertical side of the light yellow cylinder in the image above?
– Syed
Feb 10 at 12:27
• @Syed I don't know the general case, but for this special case, we can use reg = ImplicitRegion[{0 <= z <= 9 - x^2 - y^2, {x, y} ∈ Circle[]}, {x, y, z}] // Region; {reg, reg // Area} Feb 10 at 12:49
IntegrateChangeVariables[
Inactive[Integrate][f[x, y],
{x, -1, 1}, {y, -Sqrt[1 - x^2], Sqrt[1 - x^2]}],
{r, \[Theta]},
"Cartesian" -> "Polar"]


(* Inactive[Integrate][-r (-9 + r^2), {r, 0, 1}, {[Theta], -[Pi], [Pi]}] *)

Activate[%]
`

(17 [Pi])/2

• Please accept my apologies. I have split the question. It was clumsy of me. Could you please move this answer over to the new question where it would be a perfect match. Thanks.
– Syed
Feb 10 at 12:57
• What new question? Feb 10 at 13:14
• 297845
– Syed
Feb 10 at 13:15