# Strange analytical and numerical results during an integration of a complex integrand

Mma 13.2.1.0 Win 10 Pro

I am solving the following integral:

int1 = Integrate[(E^(I φ) r)/Sqrt[-1 + E^(2 I φ) r^2]*r, {r, 0,R}, {φ, -π, π}, Assumptions -> R > 1]


with the outcome:

1/4 (-I R^2 + π (-1 + R^2) + 2 I R^2 Log[R])


However the integral

int2 = Integrate[(E^(-I φ) r)/Sqrt[-1 + E^(-2 I φ) r^2]*r, {r, 0,R}, {φ, -π, π}, Assumptions -> R > 1]


evaluates to exactly the same expression. These two integrands are complex conjugated. However, the integration results are equal.

For one thing, it looks for me as a bug.

For the other thing, I need the result.

I tried to solve it numerically:

NIntegrate[(E^(I φ) r)/Sqrt[-1 + E^(2 I φ) r^2]*r, {φ, -π, π}, {r, 0, 10},


Returning

(* {1.24345*10^-14 + 4.44089*10^-16 I, -1.31465*10^-8 -
3.64292*10^-16 I, -1.31465*10^-8 - 3.64292*10^-16 I} *)


along with a lot of warnings (except for "LocalAdaptive") like "Numerical integration converging too slowly" and alike. This numerical result does not look very convincing for me.

Any idea for a workaround?

• I don't find your int1 and int2 bugs. These are improper double integrals which are not calculated by direct use of Newton-Leibniz formula. Commented Jan 26 at 16:15

Both integrals are improper because of two integrable singularities

Reduce[-1 + E^(2 I \[CurlyPhi]) r^2 ==  0 && \[CurlyPhi] > -Pi &&
\[CurlyPhi] <= Pi && r > 0, \[CurlyPhi]]


r == 1 && (\[CurlyPhi] == \[Pi] || \[CurlyPhi] == 0)

In order to calculate int1 two small disks of different radii centered at these singularities should be excluded from the domain of the integration and then passing to the limit should be done. Being lazy, I exclude an annulus Annulus[{0,0},{1 - eps,1 + eps}] with eps > 0 to this end. Now

int11 = Integrate[(E^(I \[CurlyPhi]) r)/
Sqrt[-1 + E^(2 I \[CurlyPhi]) r^2]*r, {r, 0,  1 - eps},
{\[CurlyPhi], -\[Pi], \[Pi]},  Assumptions -> eps > 0 && eps < 1]


and

int12 = Integrate[(E^(I \[CurlyPhi]) r)/
Sqrt[-1 + E^(2 I \[CurlyPhi]) r^2]*r, {r, 1 + eps, R},
{\[CurlyPhi], -\[Pi], \[Pi]},  Assumptions -> eps > 0 && eps < R - 1 && R > 1]


produce long outputs which are omitted. Next,

Limit[int11 + int12, eps -> 0, Direction -> "FromAbove", Assumptions -> R > 1]


1/2 (-\[Pi] + \[Pi] R^2 - 2 I ArcSinh[1] + 2 I R^2 ArcSinh[R] + I Log[-1 - I] - I Log[-1 + I] - I Log[1 - I] + I Log[1 + I] - I Log[2 - Sqrt[2]] + I Log[2 + Sqrt[2]] + I R^2 Log[I - R - Sqrt[-1 + R^2]] + I R^2 Log[R - Sqrt[-1 + R^2]] - I R^2 Log[I + R - Sqrt[-1 + R^2]] - I R^2 Log[-I - R + Sqrt[-1 + R^2]] - I R^2 Log[R + Sqrt[-1 + R^2]] + I R^2 Log[-I + R + Sqrt[-1 + R^2]] + I R^2 Log[1 + R - Sqrt[1 + R^2]] + I R^2 Log[1 - R + Sqrt[1 + R^2]] - I R^2 Log[-1 + R + Sqrt[1 + R^2]] - I R^2 Log[1 + R + Sqrt[1 + R^2]])

and

 int1= FullSimplify[%, Assumptions -> R > 1]


1/2 R^2 (\[Pi] + I ArcSinh[R] - I Log[I + R - Sqrt[-1 + R^2]] - I Log[2 R (1 + I R + I Sqrt[-1 + R^2])] + I Log[(-I + R + Sqrt[-1 + R^2]) (-1 + R - Sqrt[1 + R^2])] + I Log[-I (-I - R + Sqrt[-1 + R^2]) (1 + R - Sqrt[1 + R^2])])

The above result differs from yours. Let us verify int1 numerically by

  int1/. R -> 10.


0. + 0. I

and

NIntegrate[(E^(I \[CurlyPhi]) r)/Sqrt[-1 + E^(2 I \[CurlyPhi]) r^2]*
r, {\[CurlyPhi], -\[Pi], \[Pi]}, {r, 0, 10}, Method -> #,
Exclusions -> {-1 + E^(2 I \[CurlyPhi]) r^2 ==


{0.0000122805 + 2.22045*10^-16 I, -5.5682*10^-11 + 2.16165*10^-11 I, -1.31465*10^-8 - 5.27356*10^-16 I}

together with several warnings and errors. I don't know good numeric methods for multiple improper integrals. I leave int2 on your own.

Addition. Up to a constant multiplier the integral Integrate[(E^(-I φ) r)/Sqrt[-1 + E^(-2 I φ) r^2]*r, {φ, -π, π},Assumptions->r>0] is nothing but a contour integral

ContourIntegrate[1/Sqrt[1 - z^2], z \[Element] Circle[{0, 0}, r],
Assumptions -> r > 0]


ConditionalExpression[0, r <= 1]

Also

 ContourIntegrate[1/Sqrt[1 - z^2], z \[Element] Circle[{0, 0}, r],
Assumptions -> r > 1]


0

To be sure,

ContourIntegrate[1/Sqrt[1 - z^2], z \[Element] Circle[{0, 0}, 3],  WorkingPrecision -> 12,PrecisionGoal->6,AccuracyGoal->6]


3.85954244598*10^-14-2.48320221365*10^-13 I

• Thank you. I understand. Commented Jan 26 at 17:25