0
$\begingroup$

I'm new on Mathematica and have been trying to solve the following system of 8 equations with 7 variable:

8eq system

However, Mathematica takes too much time trying to solve the system. I left Mathematica working on that for 24 hours without success.

The idea is to find analytical solutions for b3, c,c2, c4, θ, ø (phi) and ω. I have tried with Solve and Reduce, but it didn't work.

I attached the code below:

Clear[\[Alpha]re, \[Alpha]i, \[Beta]re, \[Beta]i, \[Gamma]re , \
\[Gamma]i, \[Delta]re , \[Delta]i]
var = {c, c2, b3, c4, \[Omega], \[Phi], \[Theta]};
Eq1 = \[Alpha]re == 
  Cos[b3/2] Cos[
    1/4 (2 c + 2 c2 + 2 c4 + \[Pi] - 
       4 \[Theta])] Cos[\[CurlyPhi] - \[Omega]]
Eq2 = \[Alpha]i == -Cos[b3/2] Cos[\[CurlyPhi] - \[Omega]] Sin[
    1/4 (2 c + 2 c2 + 2 c4 + \[Pi] - 4 \[Theta])]
Eq3 = \[Beta]re == 
  Sin[b3/2] Sin[
    1/4 (-2 c - 2 c2 + 2 c4 + \[Pi] + 
       4 \[Theta])] Sin[\[CurlyPhi] - \[Omega]]
Eq4 = \[Beta]i == -Sin[b3/2] Sin[
    1/4 (2 c + 2 c2 - 2 c4 + \[Pi] - 
       4 \[Theta])] Sin[\[CurlyPhi] - \[Omega]]
Eq5 = \[Gamma]re == 
  Cos[1/4 (2 c + 2 c2 + 2 c4 + \[Pi] - 
       4 \[Theta])] Cos[\[CurlyPhi] - \[Omega]] Sin[b3/2]
Eq6 = \[Gamma]i == -Cos[\[CurlyPhi] - \[Omega]] Sin[b3/2] Sin[
    1/4 (2 c + 2 c2 + 2 c4 + \[Pi] - 4 \[Theta])]
Eq7 = \[Delta]re == -Cos[b3/2] Sin[
    1/4 (-2 c - 2 c2 + 2 c4 + \[Pi] + 
       4 \[Theta])] Sin[\[CurlyPhi] - \[Omega]]
Eq8 = \[Delta]i == 
  Cos[b3/2] Sin[
    1/4 (2 c + 2 c2 - 2 c4 + \[Pi] - 
       4 \[Theta])] Sin[\[CurlyPhi] - \[Omega]]
Eqs = {Eq1, Eq2, Eq3, Eq4, Eq5, Eq6, Eq7, Eq8};
Reduce[Eqs, var]
$\endgroup$
1
  • 1
    $\begingroup$ In your code in var you have Phi and in your equations you have CurlyPhi and I'm guessing that is a typo to fix. Then you want to solve for both Phi and Omega but those two only appear as a difference and no where else. I suggest you replace Phi-Omega with po, solve for po and figure out what to do with that afterwards. Then replace all your b3/2 with b and figure out b3 afterwards. Then get rid of almost all the constants in each of your 1/4 (2 c+2c2+2c4+Pi-4 Theta)` by scaling that. Then find a way to have n equations and n unknowns, make it simple. Will it solve? $\endgroup$
    – Bill
    Commented Jan 7 at 6:51

1 Answer 1

1
$\begingroup$

First, according to the @Bill's comment, we make substitutions

Eqs1 = Eqs /. {1/4 (2 c + 2 c2 + 2 c4 + \[Pi] - 4 \[Theta]) -> r, 
1/4 (-2 c - 2 c2 + 2 c4 + \[Pi] + 4 \[Theta]) ->  s,
\[CurlyPhi] - \[Omega] -> t,1/4 (2 c + 2 c2 - 2 c4 + \[Pi] - 4 \[Theta]) -> p}

{\[Alpha]re == Cos[b3/2] Cos[r] Cos[t], \[Alpha]i == -Cos[b3/2] Cos[t] Sin[ r], \[Beta]re == Sin[b3/2] Sin[s] Sin[t], \[Beta]i == -Sin[b3/2] Sin[p] Sin[ t], \[Gamma]re == Cos[r] Cos[t] Sin[b3/2], \[Gamma]i == -Cos[t] Sin[b3/2] Sin[ r], \[Delta]re == -Cos[b3/2] Sin[s] Sin[t], \[Delta]i == Cos[b3/2] Sin[p] Sin[t]}

Second, we switch from trigonometry to polynomial algebra by

Eqs2 = Union[{cb^2 + sb^2 == 1, ct^2 + st^2 == 1, cp^2 + sp^2 == 1, 
cs^2 + ss^2 == 1, cr^2 + sr^2 == 1}, 
Eqs1 /. {Cos[b3/2] -> cb, Sin[b3/2] -> sb, Cos[t] -> ct, 
Sin[t] -> st, Sin[s] -> ss, Cos[s] -> cs, Sin[p] -> sp, 
Cos[p] -> cp, Sin[r] -> sr, Cos[r] -> cr}];

Third,

Reduce[Eqs2, {cp, sp, cr, sr, cs, ss, ct, st, cb, sb}]

produces the output with LeafCount which results in 10534. I leave the rest on your own.

Addition. Another way consists in evaluating all the parameters, for example,

\[Alpha]re = 1/2; \[Alpha]i = -1/3; \[Beta]re = Sqrt[2]/2; 
\[Beta]i = 1/3; \[Gamma]re = 0; \[Gamma]i = 5/6; \[Delta]re =  1/3; \[Delta]i = -1/4;

and then

var = {c, c2, b3, c4, \[Omega], \[CurlyPhi], \[Theta]};
Eqs = {Eq1, Eq2, Eq3, Eq4, Eq5, Eq6, Eq7, Eq8};
Reduce[Eqs, var]

False

Such a result is typical.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.