Creating Lists From Loops

Question

Consider the following:

lists = Import["G:/Notebooks/Lists.csv"];

col7 = lists [[All, 7]];

For[i=0,i<101,i++,Print[Count[col7,i]]]

This will get a 100 cells printed out but what I really want to do is capture this output to another variable as a list. So far the best way I have figured out is to copy the output, edit the text, and manually paste it back in to a variable. There surely has to be a better way?

Answer 1

Generally, the solution to this kind of problems is using Table:

Table[Count[col7, i], {i, 100}]

However, in this case I suggest Tally or BinCounts:

Tally[col7]

BinCounts[col7, {0, 100, 1}]

Tally will not list elements that don't appear at all.

Answer 2

In addition Array and Map work. Thanks Mr.Wizard. There are some subtle differences in their arguments the documentation does a good job of explaining them.

I assume you were looking for counts of the occurrences of values 0 - 100 in col7.

min = 0;
max = 9; (* In your example it would be 100 *)
col7 = RandomInteger[{min, max}, max*10];

a = {}; For[i = min, i <= max, i++, AppendTo[a, Count[col7, i]]]; a

Array[Count[col7, #] &, max + 1 - min, min]

Map[Count[col7, #] &, Range[min, max]]

Table[Count[col7, i], {i, min, max}]

Sort[Tally[col7], #1[[1]] < #2[[1]] &][[All, 2]]

BinCounts[col7, {min, max + 1, 1}]

Results:

{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}
{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}
{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}
{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}
{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}
{6, 11, 14, 6, 11, 9, 7, 10, 7, 9}

The numbers will vary because of how I generated col7, but they should be the same for all six examples.

Performance results:

min = 0;
max = 100;
col7 = RandomInteger[{min, max}, 10000];