4
$\begingroup$

I want to plot this set of complex numbers in Mathematica: $$ D := \left\{\frac{1}{z}: z \in \mathbb{C}, \text{Im}(z) \ge 1, \text{Re}(z) \le \text{Im}(z), |z-1-i| \le 1\right\} $$

$\endgroup$

3 Answers 3

7
$\begingroup$

The domain of the mapping 1/z is

reg=ImplicitRegion[{y >= 1, x <= y, Abs[x + I*y - 1 - I] <= 1}, {x, y}]
RegionPlot[reg, AspectRatio -> Automatic]
RegionPlot[{x, y} ∈ reg, {x, -2, 2}, {y, -2, 2}, 
 PlotPoints -> 80, MaxRecursion -> 2]
RegionPlot[RegionMember[reg, {x, y}], {x, -2, 2}, {y, -2, 2}, 
 PlotPoints -> 80, MaxRecursion -> 2]


enter image description here

The range of the map 1/z is

ParametricPlot[ReIm[1/(x + I*y)], {x, y} ∈reg]

For the old version such 12.2, we have to use (maybe a bug)

ParametricPlot[
 ReIm[1/(x + I*y)], {x, y} ∈ DiscretizeRegion@reg]

enter image description here

$\endgroup$
6
  • $\begingroup$ Thanks, that works. I know want to change the output range (the part with AspectRation -> Automatic, I tried using RegionPlot[reg, {x, -2, 2}, {y, -2, 2}] but I get an empty plot. How can I do this? $\endgroup$
    – Tim
    Dec 13, 2023 at 13:45
  • $\begingroup$ @Tim see the updated. $\endgroup$ Dec 13, 2023 at 13:55
  • $\begingroup$ @herbertfederer Nice answer! Any idea why it doesn't work in Mathematica v12.2? Thanks! $\endgroup$ Dec 13, 2023 at 18:52
  • $\begingroup$ @UlrichNeumann Seems be a bug. Now ParametricPlot[ ReIm[1/(x + I*y)], {x, y} ∈ DiscretizeRegion@reg] $\endgroup$ Dec 13, 2023 at 19:58
  • $\begingroup$ @herbertfederer Clever, that works. Thanks! $\endgroup$ Dec 13, 2023 at 20:00
3
$\begingroup$

Just for illustrative purposes:

Parametrizing

f[r_, t_, g_] := 
 ReIm@g[ExpToTrig[(Sqrt[2] Exp[I Pi/4] + r Exp[I t])]]

Visualizing:

Manipulate[
 Column[{ParametricPlot[f[r, t, Identity], {r, 0, 1}, {t, Pi/4, Pi}, 
    Epilog -> {Red, Point[f[1, a, Identity]], Green, 
      Point[f[s, Pi/4, Identity]], Black, Point[f[w, Pi, Identity]]}],
    ParametricPlot[f[r, t, 1/# &], {r, 0, 1}, {t, Pi/4, Pi}, 
    Epilog -> {Red, Point[f[1, a, 1/# &]], Green, 
      Point[f[s, Pi/4, 1/# &]], Black, Point[f[w, Pi, 1/# &]]}]}], {a,
   Pi/4, Pi}, {s, 0, 1}, {w, 0, 1}]

enter image description here

$\endgroup$
2
$\begingroup$

Perhaps this will be useful for the purposes of visualizing complex numbers.

We can use ComplexListPlot

With

complex = 1/(x + I y);

we do

ComplexListPlot[
 Callout[#, #] & /@ 
    Flatten[Table[
      If[Im[complex] >= 1 && Re[complex] <= Im[complex] && 
        Abs[complex - 1 - I] <= 1, complex, Nothing], {x, -5, 5, 1/
       50}, {y, -5, 5, 1/50}]] // Rationalize[#, 0] & // Quiet]

plot

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.