Why does Mathematica get the infinite sum of this representation of the taylor series of $\cos^2(x)$ wrong?

Question

Bug introduced in 12.0 or earlier, persisting through 13.2 or later

---

Mathematica correctly identifies this sum as $\cos(x)$:

Sum[((-1)^n x^(2 n))/(2 n)!, {n, 0, Infinity}]

Mathematica also correctly identifies this product of sums as $\cos^2(x)$:

Sum[((-1)^i x^(2 i))/(2 i)!, {i, 0, Infinity}] Sum[((-1)^j x^(
   2 j))/(2 j)!, {j, 0, Infinity}]

However, when rearranged as this, Mathematica suddenly fails by finding $\cos^2(x) - \frac{1}{2}$ instead of $\cos^2(x)$:

Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, 0, 
  Infinity}, {j, 0, Infinity}]

It is interesting to note that it finds this sum to be the same as the above product for any finite number of terms, and only fails in the limit.

Is there a good reason for this happening?

Answer 1

Expanding on the comment by @Goofy and after reading the docs we see that:

1. "ParallelFirstToSucceed" try each method in parallel until one succeeds

2. "ParallelBestQuality" try each method in parallel and return the best result

3. "IteratedSummation" use iterated univariate summation

So, if we do

Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, 0, 
  Infinity}, {j, 0, Infinity}, Method -> "ParallelFirstToSucceed"]

or

Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, 0, 
  Infinity}, {j, 0, Infinity}, Method -> "ParallelBestQuality"]

or

Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, 0, 
  Infinity}, {j, 0, Infinity}, Method -> "IteratedSummation"]

And if we don't want to use any Method in the Sum

Limit[Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, xx, 
   Infinity}, {j, xx, Infinity}], {xx -> 0}]

or

Normal@Series[
  Sum[((-1)^i x^(2 i))/(2 i)!*((-1)^j x^(2 j))/(2 j)!, {i, xx, 
    Infinity}, {j, xx, Infinity}], {xx, 0, 0}]

all yield

Cos[x]^2

Answer 2

Vs 6 gets the correct result, but Wolfram $\alpha$ decides, too, that $$\sum_{m,n=0}^\infty \frac{ (-1)^{n+m} x^{2m+2n} }{(2n)!(2m)!} \quad \ne \quad \sum_{m=0}^\infty\left(\sum_{n=0}^\infty \frac{ (-1)^{n+m} x^{2m+2n} }{(2n)!(2m)!}\right) $$

Inspection of the double sum shows weight 1/2 only at $(n,m)=(0,0)$, but only for upper limits $m,n=\infty$

      Sum[((-1)^(m + n) x^(2 m) x^(2 n))/((2 n)! (2 m)!), 
          {n, 0, \[Infinity]}, {m, 0, \[Infinity]}] // TrigReduce 

$$\frac{1}{2} \cos (2 x)$$

      Sum[Sum[((-1)^(m+n) x^(2m) x^(2n))/((2n)!(2m)!),
               {n,0,\[Infinity]}], {m,0,\[Infinity]}]//TrigReduce

$$\frac{1}{2} (\cos (2 x)+1)$$

Today all infinite sums with 2-term recursions are expressed as hypergeometric series, a bit dangerous an attempt because of their complex definitions with cuts on the real line:

 ds= Assuming[0 < x < \[Pi]/2, 
     Sum[((-1)^(m + n) x^(2 m) x^(2 n))/((2 n)! (2 m)!), 
      {n, 2, \[Infinity]}, {m, 2, \[Infinity]}] // TrigReduce]

$$\begin{align}&\frac{113 x^{10} \, _3F_4\left(2,2,\frac{9}{2};1,\frac{11}{2},\frac{11}{2},6;-\frac{x^2}{4}\right)}{5443200}+\frac{x^{10} \, _4F_5\left(2,2,2,\frac{9}{2};1,1,\frac{11}{2},\frac{11}{2},6;-\frac{x^2}{4}\right)}{272160}\\&+\frac{x^{10} \, _5F_6\left(2,2,2,2,\frac{9}{2};1,1,1,\frac{11}{2},\frac{11}{2},6;-\frac{x^2}{4}\right)}{4082400}-\frac{8 x^{10} \, _3F_4\left(2,2,\frac{9}{2};1,\frac{11}{2},\frac{11}{2},6;-x^2\right)}{127575}\\&-\frac{x^{10} \, _4F_5\left(2,2,2,5;1,1,\frac{11}{2},6,6;-\frac{x^2}{4}\right)}{302400}-\frac{x^{10} \, _5F_6\left(2,2,2,2,5;1,1,1,\frac{11}{2},6,6;-\frac{x^2}{4}\right)}{4536000}\\&-\frac{57}{5} x^6 \, _1F_2\left(\frac{5}{2};\frac{7}{2},\frac{7}{2};-\frac{x^2}{4}\right)+\frac{32}{5} x^6 \, _1F_2\left(\frac{5}{2};\frac{7}{2},\frac{7}{2};-x^2\right)\\&-\frac{1796}{9} x^4 \, _1F_2\left(\frac{3}{2};\frac{5}{2},\frac{5}{2};-\frac{x^2}{4}\right)+\frac{32}{9} x^4 \, _1F_2\left(\frac{3}{2};\frac{5}{2},\frac{5}{2};-x^2\right)+5632 \text{Ci}(x)+\frac{797 x^6}{5400}-\\&\frac{131 x^4}{4}+2366 x^2+\frac{1711}{2} x^2 \cos (x)-30 x^2 \cos (2 x)-\\& -5632 \log (x)-\frac{10771}{2} x \sin (x)+65 x \sin (2 x) \end{align}$$

The nested sum is

   ns=Assuming[0 < x < \[Pi]/2, 
      Sum[Sum[((-1)^(m + n) x^(2 m) x^(2 n))/((2 n)! (2 m)!), 
             {n,  2, \[Infinity]}], 
        {m, 2, \[Infinity]}] // TrigReduce]

$$\frac{1}{4} \left(x^4\ - \ 4 x^2\ + \ 4 x^2 \ \cos (x)-8 \cos (x)\ + \ 2 \cos (2 x)+6\right)$$

On this level the lowest terms are equal

 Series[ds-ns,{x,0,2}]

  O[x^3]

and a plot shows identity, but an equality test seems to be to complex for the current versions, aborted after some minutes.

Only the case of lower bound 0 is showing a difference in the constant term.