Element by element concatenation of two string lists

Question

I have two lists of strings:

month = {january, february, march}
year = {2013, 2013, 2013}

I want to concatenante these element by element with the final result of the form:

{january 2013, february 2013, march 2013}

The closest I have come is the following:

Map[StringRiffle[#, " "] &, {month, year}]

Which results in:

{"january february march", "2013 2013 2013"}

Which isn't very close...but at least it doesn't result in an error.

I'm sure this is simple, but I have clearly missed something.

Thanks in advance.

Answer 1

StringRiffle /@ Transpose @ {month, year}

{"january 2013", "february 2013", "march 2013"}

Your "closest" solution would also be fine if you add Transpose:

Map[StringRiffle[#, " "] &, Transpose @ {month, year}]

{"january 2013", "february 2013", "march 2013"}

Answer 2

month = {"january", "february", "march"}
year = {"2013", "2014", "2015"}
MapThread[StringRiffle[{#1, #2}] &, {month, year}]

or

Inner[StringRiffle[{#1, #2}] &, month, year, List]

---

Result:

{"january 2013", "february 2014", "march 2015"}

Answer 3

What you posted for your data isn't actually strings, so I'll assume that it was supposed to be like this:

month = {"january", "february", "march"};
year = {"2013", "2013", "2013"};

MapThread is a useful function for performing some sort of joining of lists that have the same structure. In general it looks like this:

MapThread[f, {month, year}]
(* {f["january", "2013"], f["february", "2013"], f["march", "2013"]} *)

So, you just need to figure out what f you want. Maybe something like this:

MapThread[#1 <> " " <> #2 &, {month, year}]
(* {"january 2013", "february 2013", "march 2013"} *)

Answer 4

Grabbing from Syed

month = {"january", "february", "march"}
year = {"2013", "2014", "2015"}

One suggestion

Apply[StringJoin, Transpose /@ Transpose@{month, year}, 1]

A second one

Function[{x, y}, StringJoin[ToString /@ {x, y}], 
  Listable][month, year]

Both return

{"january2013", "february2014", "march2015"}

Not exactly a third one, but fun nonetheless

Function[, {##}, Listable][month, year]

{{"january", "2013"}, {"february", "2014"}, {"march", "2015"}}

Answer 5

month = {"january", "february", "march"}
year = {"2013", "2014", "2015"}

BlockMap[StringRiffle,Riffle[month,year],2]

(* {"january 2013", "february 2014", "march 2015"} *)

 MapThread[StringTemplate["`` ``"], {month,year}]

(* {"january 2013", "february 2014", "march 2015"} *)

Just for fun

MapThread[StringTemplate["`2` `1`", 
  CombinerFunction-> Composition[StringJoin,Capitalize]], {year,month}]

(* {"January 2013", "February 2014", "March 2015"} *)

MapThread[StringTemplate["`2` `1`", CombinerFunction -> 
  Composition[Decapitalize@*ToUpperCase,StringJoin]], {year,month}]

(*{"jANUARY 2013", "fEBRUARY 2014", "mARCH 2015"} *)

Answer 6

month = {"january", "february", "march"}; year = {"2013", "2014", "2015"};

9. Thread + DateString

Map[DateString]@Thread[{month, " ", year}]

{"january 2013", "february 2014", "march 2015"}

10. Thread + StringJoin

MapApply[StringJoin]@Thread[{month, " ", year}]

{"january 2013", "february 2014", "march 2015"} 

Activate @ Thread[Inactive[StringJoin][month, " ", year]]

{"january 2013", "february 2014", "march 2015"}

ReleaseHold @ Thread[Hold[StringJoin][month, " ", year]]

{"january 2013", "february 2014", "march 2015"}

Answer 7

11. <>

month = {"january", "february", "march"};year = {"2013", "2014", "2015"}

Table[month[[i]]<>" "<>year[[i]],{i,1,Length [month]}]

• {january 2013, february 2014, march 2015} *

Or

month[[#]]<>" "<>year[[#]]&/@Range[Length[month]]

• {january 2013, february 2014, march 2015} *

Or

StringRiffle[{mounth[[#]],year[[#]]}&/@Range[Length[month]]

• {january 2013, february 2014, march 2015} *

For responding exactly to your question, we must make year to string before:

year={2013,2014,2015};year=ToString[year];

Answer 8

Using ReplaceAll:

Transpose[{month, year}] /. x : {_, _} :> Capitalize@StringRiffle[ToString /@ x]

(* {"January 2013", "February 2013", "March 2013"} *)

Or using Cases:

Cases[Transpose[{month, year}], x_ :> Capitalize@StringRiffle[ToString /@ x]]

(* {"January 2013", "February 2013", "March 2013"} *)