1
$\begingroup$

$$\Omega^2(k) = 4(\sum\limits_{m=1}^{\infty}\frac{1-\cos(km)}{m^{1+\alpha}})(\sum\limits_{m=1}^{\infty}\frac{1-\cos(km)}{m^{1+\alpha}} - A^2)$$

Let $A = 1$ and $\alpha = 1$ and write $w(k) := \sum\limits_{m=1}^{\infty}\frac{1-\cos(km)}{m^{1+\alpha}}$. I am told that there exists a unique $k$, call it $k_{max}$, which minimizes $\Omega^2$ where $k_{max}$ satisfies $w(k_{max}) = \frac{A^2}{2}$ and $\Omega^2(k_{max}) = -A^4$.

enter image description here

$\epsilon=1$ in the above. However, in my attempt to compute this $k_{max}$

\[Alpha] = 0.7;
A = 1;
M = 5;
f[k_, \[Alpha]_, M_] := 
  Sum[(1 - Cos[k*m])/m^(1 + \[Alpha]), {m, 1, M}];
Solve[f[k, \[Alpha], M] == A^2/2 &&  
  4 f[k, \[Alpha], M] (f[k, \[Alpha], M] - A^2) == -A^4, k]

this yields an empty solution. Did I write my Mathematica code correctly?

$\endgroup$

1 Answer 1

4
$\begingroup$
$Version

(* "13.3.1 for Mac OS X ARM (64-bit) (July 24, 2023)" *)

Clear["Global`*"]

f[k_, α_] := Assuming[0 < k < Pi,
  Sum[(1 - Cos[k*m])/m^(1 + α), {m, 1, Infinity}] // Simplify]

kmax = With[{A = 1, α = 1}, 
  ArgMin[{4 f[k, α] (f[k, α] - A^2), 0 < k < Pi}, k] // 
   Simplify]

(* π - Sqrt[-2 + π^2] *)

Verifying,

{4 f[kmax, α] (f[kmax, α] - A^2) == -A^4, f[kmax, α] == A^2/2, 
   0 < kmax < Pi} /. {A -> 1, α -> 1} // FullSimplify

(* {True, True, True} *)
$\endgroup$
3
  • $\begingroup$ Why was what I wrote not yielding the same answer? $\endgroup$
    – KZ-Spectra
    Commented Nov 11, 2023 at 0:27
  • 1
    $\begingroup$ The text indicates that alpha = 1 but your code used alpha = 0.7; also you truncated the sum with M = 5 rather than using M = Infinity. $\endgroup$
    – Bob Hanlon
    Commented Nov 11, 2023 at 0:42
  • $\begingroup$ I've tried plotting the kmax values for a range of alpha, but I see lots of these kind of messages: i.imgur.com/EZkm5cq.png Does that happen because finding the value kmax is difficult for Mathematica to do? $\endgroup$
    – KZ-Spectra
    Commented Nov 11, 2023 at 17:31

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.