Distributing points on boundary (roughly) evenly

Question

How to get roughly evenly distributed mesh points along boundary?

We can see marked by red circles, that some points are too close to each other while others are too apart from each other.

Show[#, Graphics@
    Point@(Join @@ (PolygonCoordinates /@ #["BoundaryPolygons"]))] &@
 BoundaryDiscretizeGraphics[
  Text[Style["b", FontFamily -> "Cambria"]], _Text, 
  MaxCellMeasure -> {"Length" -> 1}]

Another strange thing is that setting MaxCellMeasure -> {"Length" -> 0.1} leaves ranges in the boundary with no point at all.

Answer 1

Edit

For the original code,we can subdivide the line to add some points.

polys = #["BoundaryPolygons"] &@
   BoundaryDiscretizeGraphics[
    Text[Style["b", FontFamily -> "Cambria"]], _Text, 
    MaxCellMeasure -> {"Length" -> 1}];
δ = 1/4;
lines = MeshPrimitives[#, 1] & /@ polys;
Flatten[Map[
    Subdivide[Sequence @@ First@#, Ceiling[ArcLength@#/δ]] &, 
    lines, {2}], 1] // Map@Point // Graphics

• We can use ExportString to extract the boundary curves from the fonts.( we can read https://reference.wolfram.com/language/ref/FilledCurve.html)

Clear[fonts, fillcurves];
fonts = 
 ImportString[
  ExportString[Text[Style["qH", FontFamily -> "Cambria"]], 
   "PDF"], {"PDF", "PageGraphics"}, "TextOutlines" -> True];
fillcurves = Cases[fonts, _FilledCurve, -1];
HighlightMesh[BoundaryDiscretizeGraphics[#, MaxCellMeasure -> .1], 
    0] & /@ fillcurves // Show

• Similar with https://mathematica.stackexchange.com/a/289439/72111

Clear["Global`*"];
lines = MeshPrimitives[
   BoundaryDiscretizeGraphics[
    ImportString[
      ExportString[Text[Style["b", FontFamily -> "Cambria"]], 
       "PDF"], {"PDF", "PageGraphics"}, "TextOutlines" -> True][[1]], 
    MaxCellMeasure -> .1], 1, "Multicells" -> True];
δ = .5;
MapThread[
  ListLinePlot[#1 /. Line -> Apply@Join, 
    MeshFunctions -> {0 &, "ArcLength"}, Mesh -> {#2}, 
    MeshStyle -> Red, AspectRatio -> Automatic, 
    Axes -> False] &, {lines, 
   Subdivide /@ Floor /@ (ArcLength /@ lines/δ)}] // Show

Answer 2

Resample discrete points using LineScaledCoordinate.

Clear["`*"]; Needs["GraphUtilities`"]; num = 80;
reg = BoundaryDiscretizeRegion[
   BoundaryDiscretizeGraphics[
    Text[Style["b", Bold, FontFamily -> "Times"]], _Text, 
    MaxCellMeasure -> {"Length" -> 1}]];
pts1 = Map[Apply[Join], 
   Cases[MeshPrimitives[reg, 1, Multicells -> True], 
    Line[pts_, ___] :> pts, Infinity]];
ptlen = pts1 // Length;
Table[rept[i] = 
   Table[LineScaledCoordinate[pts1[[i]], j], {j, 0, 1, 1./num}], {i, 
   1, ptlen, 1}];
{Graphics[{RandomColor[], Point@#}] & /@ Array[rept, ptlen], 
 Graphics[{RandomColor[], Point /@ Array[rept, ptlen]}]}