How to fold output cells by default?

Question

In Mathematica the default behavior of output cells is to pop up after the kernel has processed the input cells and got a result. I know I could add ; in the end of input cells to disable output cells, which are often too messy in the middle of my calculations and usually I don't really care what they are, from appearing. However sometimes I need to go back and check some stuff, so it is still necessary to keep those intermediate results there. Then my questions is that is it possible to "fold" output cells? By "folding" I mean it would look as if I manually double click the cell, so the output cell will be hidden and an arrow appears next to the input cell. I tried to find some related settings described in this post, but nothing useful there. Thanks!

Answer 1

I'm slow, but eventually I get there. ;-) You need CellEpilog to make the behavior automatic on evaluation of any cell. Importing the code from my autoFoldOutput function:

SetOptions[EvaluationNotebook[], 
 CellEpilog :> 
   (SelectionMove[EvaluationNotebook[], All, EvaluationCell];
    FrontEndTokenExecute["SelectionCloseUnselectedCells"])
]

Simply evaluate that in your Notebook and all output groups will be automatically closed when they are created. You may replace EvaluationNotebook[] with $FrontEndSession if you want to affect all Notebooks during the session or with $FrontEnd to persistently affect all Notebooks.

Answer 2

Not sure if this is what you're looking for, but the Cell menu has an item that collapses open cells:

Here I highlighted the open input/output cells and then collapsed them to get the following:

If your question is about automatically and immediately collapsing every output cell, then that's a different story. It will most likely involve this answer.

Answer 3

Here are two other alternatives:

SetOptions[EvaluationCell[], 
 "GeneratedCellStyles" -> {"Output" -> {"Output", CellOpen -> False}}]

And:

Dynamic[
 SetOptions[EvaluationCell[], CellOpen -> False];
 myHiddenContent
 ]

You could even make a one-shot, so that the cell initially displays unopened, but the user has the option to manually open it, without Dynamic getting in the way:

Evaluate[closeIt = True];
Dynamic[
 If[closeIt,
  SetOptions[EvaluationCell[], CellOpen -> False];
  closeIt = False
  ];
 myHiddenContent
 ]

(A more complete solution would use DynamicModule too)

The first solution prevents any "flashing" of an output cell that is temporarily shown before then being hidden. If you put the SetOptions piece of code as the first line in Dynamic in the second solution, in practice, I don't notice any flashing. Using other methods that don't close the cell until after it has been shown with content in it might result in flashing of temporary contents on the screen.