Stopping mathematica from rearranging elements in a list

Question

I have the following list

set1={-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1}

How when I am doing

Complement[set1, {-1/x}]

Then it gives

{1, -(1/x) + x/2 - 2 Log[x] - Log[x]/x}

then it rearranges the third element to the second element and vice versa. This is dangerous for my case. How to stop this?

Answer 1

You can use DeleteElements which came with V 13.1:

set1 = {-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1}

DeleteElements[set1, {-1/x}]

Versions prior to 13.1 could use f.e.

Delete[set1, Position[set1, -1/x, 1]]

or (since V 12.1)

SubsetReplace[set1, {-1/x} -> Nothing]

Both give the expected result:

Answer 2

UniqueElements[{set1,{ -1/x}}][[1]]

(* {-x^(-1)+x/2-2*Log[x]-Log[x]/x,1} *)

Answer 3

set1 = {-1/x, -1/x + x/2 - 2 Log[x] - Log[x]/x, 1};

Fold[DeleteCases, set1, {-1/x}]
(*    {-1/x + x/2 - 2 Log[x] - Log[x]/x, 1}    *)

Answer 4

If I understand correctly, this is what you need

set1 = {-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1}
SortBy[Complement[set1, {-1/x}], Position[set1, #] &]

Answer 5

Instead of applying "Complement" to the whole list set1, you may apply it to the single elements of set1 like:

set1 = {-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1};
Complement[{#}, {-1/x}] & /@ set1 // Flatten

{-(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1}

Answer 6

or use filter, in Mathematica it's Select

{-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1} //
Select[# =!= -1/x&]

Answer 7

set1 = {-1/x, -1/x + x/2 - 2  Log[x] - Log[x]/x, 1};

Using DeleteCases with a condition, as follows:

DeleteCases[set1, s_ /; MatchQ[s, -1/x]]

{-(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1}

Answer 8

set1 = {-(1/x), -(1/x) + x/2 - 2 Log[x] - Log[x]/x, 1};

Using UnsortedComplement by George Beck

UnsortedComplement = ResourceFunction["UnsortedComplement"];

UnsortedComplement[set1, {-1/x}]