Make association with deepest rules from nested association

Question

I want to extract only the deepest level of association in a nested associations.

An example of input data is

<|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>

and I need to get

<|a -> 1, x -> p, z -> 3, w -> "a"|>

I have seen several questions similar to this but I have not been able to solve the problem.

What is the best way to do this?

Thanks!

Answer 1

test1 = <|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>
Association[Level[test1 /. Association -> List, {-2}]]
(* <|a -> 1, x -> p, z -> 3, w -> "a"|> *)

Update

To address the comment about needing to handle the cases where the values of the lowest level associations might be lists...

test2 = <|a -> 1, b -> <|c -> 1, d -> {2, 3}|>|>
Association[Normal[test1] //. (_ -> val_Association) :> Splice[Normal[val]]]
(* <|a -> 1, x -> p, z -> 3, w -> "a"|> *)

Association[Normal[test2] //. (_ -> val_Association) :> Splice[Normal[val]]]
(* <|a -> 1, c -> 1, d -> {2, 3}|> *)

Probably want to bundle into a function:

AssociationLeaves[a_Association] := 
  Association[Normal[a] //. (_ -> val_Association) :> Splice[Normal[val]]]

Answer 2

asc = <|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>

asc /. Association -> List // Level[#, {-2}] & // Association

<|a -> 1, x -> p, z -> 3, w -> "a"|>

---

Or

Normal@asc //. {HoldPattern[a_ -> b_ /; ! AssociationQ[b]] :> a -> b, 
    HoldPattern[a_ -> b_ /; AssociationQ[b]] :> Normal@b} // 
  Flatten // Association

Result:

<|a -> 1, x -> p, z -> 3, w -> "a"|>

Answer 3

flattenA // ClearAll
flattenA[a_Association]     := Association @ Flatten @ KeyValueMap[flattenA] @ a
flattenA[k_, v_Association] := KeyValueMap[flattenA] @ v;
flattenA[k_, v_]            := k -> v

flattenA@<|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>

<|a -> 1, x -> p, z -> 3, w -> "a"|>

Answer 4

asc = <|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>;

NestWhile[
 Association@
   KeyValueMap[
    If[AssociationQ@#2, #2, # -> #2] &, #] &, asc, UnsameQ, 2]

(* Output *)
<|a -> 1, x -> p, z -> 3, w -> "a"|>

Answer 5

asc = <|a -> 1, b -> <|x -> p, y -> <|z -> 3, w -> "a"|>|>|>;

Using Fold and MapAt

Association @ Flatten @ Fold[
   MapAt[Last, ##] &,
   asc /. Association :> List,
   {2, {2, 2}}]

<|a -> 1, x -> p, z -> 3, w -> "a"|>