How to Add Inner Squares to Bar Chart Using BarChart[] Function?

Question

I need to create a couple of bar charts, and I'm using the BarChart built-in function.

Currently, I have managed to make them look like the image on the left.

BarChart[Range[5], BarSpacing -> None, AspectRatio -> {1, 1}]

However, I would like to add the inner squares to each bar on the chart (as shown in the image on the right), and I'm not sure how to achieve this.

Any ideas? I would like to avoid using another function if possible.

Answer 1

1. ChartElementFunction

We can use a custom ChartElementFunction to add lines to rectangles:

ClearAll[cEF]
cEF = Module[{xr = #[[1]]}, 
 {ChartElementData["Rectangle"][##], 
  Directive[CapForm["Butt"], Black, Thickness[Small], Opacity[0.67]], 
  If[#[[2, 2]] > 0, Map[Line[Thread[{xr, #}]] &]@Most@Range[#[[2, 2]]], {}]}] &;

Examples:

dt1 = Range[5];

BarChart[dt1, AspectRatio -> 1,  BarSpacing -> {0, 0}, 
 ChartElementFunction -> cEF]

SeedRandom[7];

dt2 = RandomInteger[12, 7];

BarChart[dt2, AspectRatio -> 1,  BarSpacing -> {0, 0}, 
 ChartElementFunction -> cEF]

2. ChartElements

BarChart[Range[5], 
 ChartElements -> 
    Graphics[Rectangle[], PlotRangePadding -> 0, ImagePadding -> None], 
 AspectRatio -> 1, 
 BarSpacing -> {0, 0}]

Answer 2

Needs["NDSolve`FEM`"]; 

addLines = ReplaceAll[r: Rectangle[a_, b_, __] :> 
 {r, First @ 
  ToElementMesh[Rectangle[a, b], 
    "MeshOrder" -> 1, MaxCellMeasure -> {"Length" -> 1}]["Wireframe"]}]

Examples:

dt1 = Range[5];

BarChart[Range[5], DisplayFunction -> addLines, 
  AspectRatio -> 1, BarSpacing -> {0, 0}]

SeedRandom[7];

dt2 = RandomInteger[12, 7];

BarChart[dt2, DisplayFunction -> addLines, 
  AspectRatio -> 1, BarSpacing -> {0, 0}]