Substitution of list elements

Question

I have two lists of string elements:

  lis = {{"Abc","Def"},{"Ghi","Abc"},{"Mno","Pqrs"}};

  abbrPool = {{"Abc","A"},{"Mno","M"}};

I would like to replace certain elements in the first list with the matching second elements from the second list, to give:

  res = {{"A","Def"},{"Ghi","A"},{"M","Pqrs"}}

I can do this by brute force using Cases/DeleteCases, but wonder if there is a more elegant solution.

Answer 1

Use ReplaceAll.

lis /. Rule @@@ abbrPool

Answer 2

ReplaceAt[MapApply[Rule] @ abbrPool, {All, 1}] @ lis

{{"A", "Def"}, {"Ghi", "Abc"}, {"M", "Pqrs"}}

Answer 3

Another way using AssociationThread and Lookup:

Map[Lookup[AssociationThread @@ Transpose[abbrPool], #, #] &, lis, {2}] === res

(*True*)

Or using Replace:

Replace[lis, Rule @@@ abbrPool, {2}] === res

(*True*)

Answer 4

Using Lookup:

lis = {{"Abc", "Def"}, {"Ghi", "Abc"}, {"Mno", "Pqrs"}};
abbrPool = {{"Abc", "A"}, {"Mno", "M"}};

lut = Rule @@@ abbrPool
Map[Lookup[lut, #, #] &, lis, {2}]

{{"A", "Def"}, {"Ghi", "A"}, {"M", "Pqrs"}}