Selectively deleting elements of a list

Question

I have a list of strings:

  lis = {{"w", "u"}, {"q", "r"}, {"z"}, {"d", "e"}, {"f"}, {"g", "h"}, {"o"}}

I would like to delete all single-element members of this list to give:

  res = {{"w","u"}, {"q","r"}, {"d","e"}, {"g","h"}}

  SequenceCases[lis, {{a_, b_}, {_}, {c_, d_}} :> {{a, b}, {c, d}}, Overlaps -> True]

fails. Apologies for this simple question!

$\begingroup$ res = DeleteCases[lis, _List?(Length[#] < 2 &)] $\endgroup$
– Bob Hanlon
Sep 19 at 4:11 — Bob Hanlon, Sep 19 at 4:11
$\begingroup$ DeleteCases[lis, {_}] $\endgroup$
– Syed
Sep 19 at 4:12 — Syed, Sep 19 at 4:12
$\begingroup$ Cases[lis,{x_,y_}] $\endgroup$
– user1066
Sep 19 at 4:17 — user1066, Sep 19 at 4:17

Vitaliy Kaurov · Accepted Answer · 2023-09-19 04:12:08Z

2

Avoiding patterns:

Select[lis, Length[#] > 1 &]
{{w,u},{q,r},{d,e},{g,h}}

answered Sep 19 at 4:12

Vitaliy Kaurov

70.8k9 gold badges200 silver badges347 bronze badges

Add a comment |

E. Chan-López · Accepted Answer · 2023-09-19 05:01:35Z

2

Another way to do this using ReplaceAll:

ReplaceAll[lis, x : {_} :> Nothing]

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

Also, using Cases:

Cases[lis, x : {__} /; Length[x] > 1]

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

answered Sep 19 at 5:01

E. Chan-López

11.3k2 gold badges16 silver badges34 bronze badges

Add a comment |

eldo · Accepted Answer · 2023-09-19 06:40:47Z

2

Since your try with SequenceCases failed

Join @@ SequenceCases[lis, {{_, _} ..}]

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

Or

SequenceReplace[{{_} ..} :> Nothing] @ lis

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

In addition to the answers already given better candidates would include

Cases[{_, _}] @ lis

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

and

 Pick[lis, Length /@ lis, 2]

{{"w", "u"}, {"q", "r"}, {"d", "e"}, {"g", "h"}}

answered Sep 19 at 5:59

eldo

40.3k2 gold badges40 silver badges103 bronze badges

Add a comment |

3 Answers 3